Question

我一直在努力研究上周问过的一个问题的变体。

我必须将每个部分的第一个和最后一个页码输出到一个包含两行的表中。

我对如何将两行表与Muenchian分组方法

进行整合感到困惑

我需要的是XSLT 1.0解决方案。我在下面有一个解决方案，但我需要两行。

任何建议或指导都会非常感激。

输入：

<root>
  <page number="1" section="Arsenal">Arsenal</page> 
  <page number="2" section="Arsenal">Arsenal</page> 
  <page number="3" section="Arsenal">Arsenal</page> 
  <page number="4" section="Arsenal">Arsenal</page> 
  <page number="5" section="Arsenal">Arsenal</page> 
  <page number="6" section="Arsenal">Arsenal</page> 
  <page number="7" section="Chelsea">Chelsea</page> 
  <page number="8" section="Chelsea">Chelsea</page> 
  <page number="9" section="Chelsea">Chelsea</page> 
  <page number="10" section="Chelsea">Chelsea</page> 
  <page number="11" section="Chelsea">Chelsea</page> 
  <page number="12" section="Chelsea">Chelsea</page> 
  <page number="13" section="ManUnited">ManUnited</page> 
  <page number="14" section="ManUnited">ManUnited</page> 
  <page number="15" section="ManUnited">ManUnited</page> 
  <page number="16" section="ManUnited">ManUnited</page> 
  <page number="17" section="ManUnited">ManUnited</page> 
  <page number="18" section="ManUnited">ManUnited</page> 
  <page number="19" section="ManCity">ManCity</page> 
  <page number="20" section="ManCity">ManCity</page> 
  <page number="21" section="ManCity">ManCity</page> 
  <page number="22" section="ManCity">ManCity</page> 
  <page number="23" section="ManCity">ManCity</page> 
  <page number="24" section="ManCity">ManCity</page> 
 </root>

输出：

<table>
<tr>
<td>Arsenal</td>
<td></td>
<td>Chelsea</td>
<td></td>
<td>ManU</td>
<td></td>
<td>ManCity</td>
<td></td>
</tr>
<tr>
<td>1</td>
<td>6</td>
<td>7</td>
<td>12</td>
<td>13</td>
<td>18</td>
<td>19</td>
<td>24</td>
</tr>
</table>

这是我目前的XSLT逻辑。

<table>
<tr>
<xsl:apply-templates select="page[generate-id() = generate-id(key('kSection', @section))]"/>
</tr>                       
</table>
</xsl:template> 
<xsl:template match="page">
<td>
<xsl:value-of select="@section"/>
</td>
<td>
<xsl:value-of select="@number"/>
</td>
<td>
<xsl:value-of select="key('kSection', @section)[last()]/@number"/>
</td>
</xsl:template>
</xsl:stylesheet>

关心JJ。

Answer 1

首先，您需要明智地对section进行分组，然后获取for-each中的第一个和最后一个节点

Group by `section`
  for-each `section`
    if position =1 or position = last
      print it

这是xsl 1.0分组示例参考。希望你能继续

XSLT select only last version element in rowset

**在xslt **

<xsl:key name="k" match="page" use="@section"/>

<xsl:template match="/root">
    <table border="1">
        <tr>
            <xsl:for-each select="page[generate-id() = generate-id(key('k', @section))]">
                <td  colspan="2">
                    <xsl:value-of select="."/>
                </td>
            </xsl:for-each>
        </tr>    
        <tr>
        <xsl:for-each select="page[generate-id() = generate-id(key('k', @section))]">
            <xsl:variable name="key">
                <xsl:value-of select="."/>
            </xsl:variable>
            <xsl:for-each select="../page[@section=$key]">
                <xsl:if test="(position() = 1) or (position() = last())">
                    <td>
                        <xsl:value-of select="current()/@number"/>
                    </td>
                </xsl:if>
            </xsl:for-each>
        </xsl:for-each>
        </tr>
    </table>
</xsl:template>

Answer 2

使用：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>

  <xsl:key name="k" match="page" use="@section"/>

  <xsl:template match="/root">
    <table>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]"/>
      </tr>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]" mode="page"/>
      </tr>
    </table>
  </xsl:template>

  <xsl:template match="page">
    <td>
      <xsl:value-of select="."/>
    </td>
    <td></td>
  </xsl:template>

  <xsl:template match="page" mode="page">
    <td>
      <xsl:value-of select="@number"/>
    </td>
    <td>
      <xsl:value-of select="key('k', @section)[last()]/@number"/>
    </td>
  </xsl:template>

</xsl:stylesheet>

输出：

<table>
  <tr>
    <td>Arsenal</td>
    <td />
    <td>Chelsea</td>
    <td />
    <td>ManUnited</td>
    <td />
    <td>ManCity</td>
    <td />
  </tr>
  <tr>
    <td>1</td>
    <td>6</td>
    <td>7</td>
    <td>12</td>
    <td>13</td>
    <td>18</td>
    <td>19</td>
    <td>24</td>
  </tr>
</table>

XSL for Xml to table转换为两行和多列

2 个答案: