Question

最初，我使用AutoHotkey与Arduino进行通信，但是我发现几个小时后没有向Arduino发送任何内容（Arduino每十秒发送一次'心跳'），连接会冻结或者失败。

现在我正在尝试通过带有the RS-232 library的C ++程序的串行连接来控制Arduino。

但是我遇到了同样的问题。该程序每隔20秒对Arduino进行一次ping操作，然后Arduino会报告一小段信息。几个小时后，连接就死了，我的C ++程序只是坐在那里ping而没有响应。 Arduino有一个看门狗，我可以验证它是否仍在工作时连接不是，所以我相信我的问题在于串行的某种固有超时...除了连接正在被使用..

我很感激任何帮助找出我需要做些什么来保持串行连接活着，计算机必须能够将数据发送到Arduino 24/7。

我正在Code::Blocks上编译，并在Windows 7上运行该程序。

我对C ++或C不是很熟悉，所以如果你在程序中找到其他愚蠢的东西，请告诉我。

的main.cpp

/**************************************************

  File: main.cpp
  Purpose: Simple demo that receives characters from
           the serial port and print them on the
           screen.

**************************************************/

#include <stdlib.h>
#include <iostream>

#ifdef _WIN32
    #include <Windows.h>
#else
    #include <unistd.h>
#endif

#include "rs232.h"

using namespace std;

int main()
{
    int debug = 0;
    int i = 0, n,
    cport_nr = 5,        /* /dev/ttyS5 (COM6 on Windows) */
    bdrate = 9600;       /* 9600 baud */

    unsigned char buf[4096];

    if(OpenComport(cport_nr, bdrate))
    {
        cout << "Can not open comport\n";
        return(0);
    }

    while(1)
    {
        if (debug)
        {
            printf("Entering While(1) loop. \n");
        }

        n = PollComport(cport_nr, buf, 4095);

        if(n > 0)
        {
            buf[n] = 0;   /* always put a "null" at the end of a string! */

            /* for(i=0; i < n; i++)
            {
                if(buf[i] < 32)  // replace unreadable control-codes by dots
                {
                  buf[i] = '.';
                }
            } */

            //printf("\n\n\nreceived %i bytes: %s\n\n", n, (char *)buf);
            cout << endl << endl << endl << (char *)buf;
        }

        if (SendByte(cport_nr, 83))
        {
            printf("\n\nSending data didn't work. \n\n");
        }
        else
        {
            cout << "\nSent [S]\n";
        }

        i = 0;

        #ifdef _WIN32
            Sleep(10000);  /* It's ugly to use a sleeptimer, in a real program, change
                              the while-loop into a (interrupt) timerroutine. */
        #else
            usleep(10000000);  /* Sleep for 100 milliSeconds */
        #endif
    }
    return(0);
}

Arduino文件

//
// SuiteLock v.2.1a
// By: Chris Bero (bigbero@gmail.com)
// Last Updated: 11.4.2012
//

#include <Servo.h>
#include <avr/wdt.h>

// Pin Constants:
const int servoPin = 9;
const int doorbtn = 3;

// Not sure if I'm still going to use these...
const int ledGND = 4;
const int ledVCC = 5;
const int servDelay = 600; // The delay allowing for the servo to complete an action.

//Variables:
int doorState = 0;  // The value returned by the door button (0 or 1).
int servState = 90;  // The position of the servo in degrees (0 through 180).
unsigned long prevMillis = 0;
unsigned long progCycles = 0;
int serialByte = 0;
int lastSerial = 0;
int smallBlink = 0;
bool dostatus = false; // Determine whether to send sys status.
Servo serv;

// Set up the environment.
void setup()
{
    wdt_enable(WDTO_4S);
    pinMode(doorbtn, INPUT);
    pinMode(ledGND, OUTPUT);
    pinMode(ledVCC, OUTPUT);
    pinMode(servoPin, OUTPUT);
    digitalWrite(ledGND, LOW);
    serv.attach(servoPin);
    Serial.begin(9600);
    prevMillis = millis();
}

////////////////////////////////////////////////
// Statuser - Sends system status to Serial
/////////////////////////////////////////////
int statuser ()
{
    wdt_reset();
    Serial.println("[Start]"); //Start Of Transmission
    delay(15);
    unsigned long currentMillis = millis();
    refresh();
    Serial.print("\tTime Alive: ");
    int hr = ((currentMillis/1000)/3600);
    int mn = (((currentMillis/1000)-(hr*3600))/60);
    int sc = ((currentMillis/1000)-(hr*3600)-(mn*60));
    Serial.print(hr);
    Serial.print(":");
    Serial.print(mn);
    Serial.print(":");
    Serial.println(sc);
    Serial.print("\tNum of Program Cycles: ");
    Serial.println(progCycles);
    Serial.print("\tAvg Cycles per Second: ");
    int cps = (progCycles/(currentMillis/1000));
    Serial.println(cps);
    Serial.print("\tDoorState: ");
    Serial.println(doorState);
    Serial.print("\tServo Position: ");
    Serial.println(servState);
    Serial.print("\tLast Serial Byte: ");
    Serial.println(lastSerial);
    delay(15);
    Serial.println("[End]"); //End Of Transmission
    return(0);
}

////////////////////////
// Lock the door.
/////////////////////
int locker()
{
    wdt_reset();

    // Check the button states.
    refresh();

    // Make sure the door is closed.
    do
    {
        wdt_reset();
        delay(500);
        refresh();
    } while(doorState == LOW);

    // Turn on the locking LED during the servo movement.
    digitalWrite(ledVCC, HIGH);

    wdt_reset();

    // Tell the servo to turn to 20 degrees.
    serv.write(20);

    // Give the servo time to complete the turn.
    delay(servDelay);

    wdt_reset();

    // Turn the servo opp direction to reset.
    serv.write(90);

    // Wait for the servo to reach it's reset point.
    delay(servDelay);

    // Turn off the cool little LED.
    digitalWrite(ledVCC, LOW);

    // Call parents for 11pm checkup and tell them everything's A-OK.
    return(0);
}

/////////////////////////
// Unlock the door.
//////////////////////
int unlocker ()
{
    wdt_reset();

    // Check the pin states.
    refresh();

    // Turn on the status LED.
    digitalWrite(ledVCC, HIGH);

    wdt_reset();

    // Turn servo to 170 degrees to unlock the door.
    serv.write(170);

    // Wait for servo motion to complete.
    delay(servDelay);

    wdt_reset();

    // Reset the servo to 90 degrees.
    serv.write(90);

    // Wait for reset motion to complete.
    delay(servDelay);

    // Turn off LED.
    digitalWrite(ledVCC, LOW);

    return(0);
}

///////////////////////////////
// Refresh button states.
/////////////////////////////
void refresh ()
{
    wdt_reset();
    doorState = digitalRead(doorbtn);
    servState = serv.read();
}

///////////////////////
// Main function.
////////////////////
void loop()
{
    wdt_reset();

    // Blink the LED every so many turn overs of the function.
    if (smallBlink == 5)
    {
        smallBlink = 0;
        digitalWrite(ledVCC, HIGH);
        delay(300);
        digitalWrite(ledVCC, LOW);
    }

    // Status.
    if(dostatus == true)
    {
        unsigned long currentMillis = millis();
        if ((currentMillis - prevMillis) > 4000)
        {
            prevMillis = currentMillis;
            statuser();
        }
    }

    // Refresh button states.
    refresh();

    // Is the door closed and not locked? *Gasp*
    if ((doorState == LOW))
    {
        // Fix it.
        while (doorState == LOW)
        {
            wdt_reset();
            delay(500);
            refresh();
        }
        locker();
    }

    // Check for available communications.
    if (Serial.available() > 0)
    {
        // Reset the serialByte, done for debugging.
        serialByte = 0;
        wdt_reset();
        // Read the serialByte.
        serialByte = Serial.read();
        lastSerial = serialByte;
    }

    // Act on the byte data.
    if (serialByte == 'U')
    {
        // Let someone in.
        unlocker();
        // Wait for the door to change states.
        delay(1000);
    }
    if (serialByte == 'L')
    {
        locker();
        delay(1000);
    }
    if (serialByte == 'S')
    {
        statuser();
        delay(200);
    }

    // Clean serialByte for debugging.
    serialByte = 0;

    // Count through program cycles.
    progCycles++;
    smallBlink++;
}

我调整了C ++程序以打开comport，发送'S'，然后关闭comport并等待。然后我让它循环程序，以便它将继续打开和关闭端口。我希望这可以保持连接达到几小时的标记和超时或其他。相反，程序成功循环了一个小时，然后突然无法打开COM端口...这完全让我感到震惊，我不知道该怎么办......

如果CrazyCasta是正确的，而且只是我的Arduino与笔记本电脑的连接有问题，有没有办法重置连接而不必先重新启动计算机？

Answer 1

正如CrazyCasta所说，这是一个硬件问题。我能够通过在Arduino和计算机之间移除一根9英尺（2.7米）的USB延长线解决问题。

截至今天早上，连接已经存在了10个小时，比之前的测试时间长了7个小时。我希望可以说这是固定的。

C ++ Arduino串行连接超时

的main.cpp

Arduino文件

1 个答案: