Question

有没有人知道如何在Perl中以完全相同的方式随机混洗两个数组？例如，假设我有这两个数组：

在洗牌之前：阵列1：1,2,3,4,5 数组2：a，b，c，d，e

改组之后：阵列1：2,4,5,3,1 数组2：b，d，e，c，a

因此每个数组中的每个元素都绑定到它的等效元素。

Answer 1

尝试（像这样）：

use List::Util qw(shuffle);
my @list1 = qw(a b c d e);
my @list2 = qw(f g h i j);
my @order = shuffle 0..$#list1;
print @list1[@order];
print @list2[@order];

Answer 2

首先：并行数组是错误代码的潜在迹象;你应该看看你是否可以使用一系列对象或哈希值，并为自己省去麻烦。

尽管如此：

use List::Util qw(shuffle);

sub shuffle_together {
  my (@arrays) = @_;

  my $length = @{ $arrays[0] };

  for my $array (@arrays) {
    die "Arrays weren't all the same length" if @$array != $length;
  }

  my @shuffle_order = shuffle (0 .. $length - 1);

  return map {
    [ @{$_}[@shuffle_order] ]
  } @arrays;
}

my ($numbers, $letters) = shuffle_together [1,2,3,4,5], ['a','b','c','d','e'];

基本上，使用shuffle以随机顺序生成索引列表，然后使用相同的索引列表对所有数组进行切片。

Answer 3

使用List::Util shuffle来混洗索引列表并将结果映射到数组中。

use strict;
use warnings;

use List::Util qw(shuffle);

my @array1 = qw( a b c d e );
my @array2 = 1..5;

my @indexes = shuffle 0..$#array1;
my @shuffle1 = map $array1[$_], @indexes;
my @shuffle2 = map $array2[$_], @indexes;

<强>更新使用Chris Jester-Young的解决方案。 Array slices是我应该想到的更好的选择。

Answer 4

这是另一种方式：

use strict;
use warnings;

use List::AllUtils qw(pairwise shuffle);

my @list1 = qw(a b c d e);
my @list2 = qw(f g h i j);

my @shuffled_pairs = shuffle pairwise{[$a, $b]} @list1, @list2;

for my $pair ( @shuffled_pairs ) {
    print "$pair->[0]\t$pair->[1]\n";
}

输出：

C:\Temp> sfl
e       j
b       g
d       i
a       f
c       h

这样，您可以直接在@shuffled_pairs上进行迭代，而无需为索引保留额外的数组，并避免使用C风格的循环。

如何在Perl中以完全相同的方式对两个数组进行洗牌？

4 个答案: