我有一个包含图像网址的列表，我想用XSL解析和显示，但我只想要前3张图片。
e.g。
<xsl:value-of select="@Icons" />
返回：
['http://www.test.com/image1.jpg',
'http://www.test.com/image2.jpg',
'http://www.test.com/image3.jpg',
'http://www.test.com/image4.jpg',
'http://www.test.com/image5.jpg']
最终输出应为：
<img src="http://www.test.com/image1.jpg" alt=""/>
<img src="http://www.test.com/image2.jpg" alt=""/>
<img src="http://www.test.com/image3.jpg" alt=""/>
我有部分代码来挑选前3个项目，但我不确定如何解析列表并以html显示图像。
<xsl:template name="recurse_till_ten">
<xsl:param name="num">1</xsl:param>
<xsl:if test="not($num = 3)">
//Parasing list here
<xsl:call-template name="recurse_till_ten">
<xsl:with-param name="num">
<xsl:value-of select="$num + 1">
</xsl:with-param>
</xsl:call-template>
</xsl:if>
</xsl:template>
答案 0 :(得分：1)
这个XSLT 1.0样式表...
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />
<xsl:template match="/">
<xsl:variable name="strip-chars" select=""[]''"" />
<xsl:for-each select="*">
<xsl:copy>
<xsl:call-template name="tokenize">
<xsl:with-param name="content" select="concat(translate(@Icons,$strip-chars,''),',')" />
<xsl:with-param name="count" select="3" />
</xsl:call-template>
</xsl:copy>
</xsl:for-each>
</xsl:template>
<xsl:template name="tokenize">
<xsl:param name="content" />
<xsl:param name="count" />
<xsl:if test="contains($content,',') and $count > 0">
<img src="{substring-before($content,',')}" alt="" />
<xsl:call-template name="tokenize">
<xsl:with-param name="content" select="normalize-space(substring-after($content,','))" />
<xsl:with-param name="count" select="$count - 1" />
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
...当应用于此输入文档时......
<t Icons="['http://www.test.com/image1.jpg',
'http://www.test.com/image2.jpg',
'http://www.test.com/image3.jpg',
'http://www.test.com/image4.jpg',
'http://www.test.com/image5.jpg']"/>
......会产生......
<t>
<img src="http://www.test.com/image1.jpg" alt="" />
<img src="http://www.test.com/image2.jpg" alt="" />
<img src="http://www.test.com/image3.jpg" alt="" />
</t>
当应用于这个简短的输入文档时......
<t Icons="['http://www.test.com/image1.jpg',
'http://www.test.com/image2.jpg']"/>
... ...产量
<t>
<img src="http://www.test.com/image1.jpg" alt="" />
<img src="http://www.test.com/image2.jpg" alt="" />
</t>
Suresh的解决方案，在编辑时，不适用于图像数量为3或更少的第二个用例。
使用带有这样的样式表的XSLT 2.0，可以更简单，更高效，更可扩展地实现相同的结果......
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />
<xsl:template match="/">
<xsl:for-each select="*">
<xsl:copy>
<xsl:variable name="image-elements" as="element()*">
<xsl:analyze-string select="@Icons" regex="'([^']*)'(,|\])" >
<xsl:matching-substring>
<img src="{regex-group(1)}" alt="" />
</xsl:matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:copy-of select="$image-elements[not(position() > 3)]" />
</xsl:copy>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
有兴趣的是，这里是使用纯XPATH的XSLT 2.0的变体。
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />
<xsl:template match="/">
<xsl:for-each select="*">
<xsl:copy>
<xsl:for-each select="(for $i in tokenize(@Icons,',') return
replace($i,'.*''([^'']*)''.*','$1'))
[not(position() > 3)]">
<img src="{.}" alt="" />
</xsl:for-each>
</xsl:copy>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
与Dimitre会面以获得更简洁的XSLT 2.0解决方案。他使用的是一个略有不同的输入，里面没有方括号。看看Dimitre的解决方案，我可以看到一个调整，使其显着缩小。
这个XSLT 2.0样式表是对Dimitre解决方案的一个调整，是所有解决方案中最严格的，并且作为奖励适用于我的输入文档和他的形式，以生成相同且正确的结果文档。
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/">
<xsl:for-each select="tokenize(/*/@Icons, '\[?\s*''\s*,?\]?')[.][position() le 3]">
<img src="{.}" alt=""/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
答案 1 :(得分：1)
更短的XSLT 2.0解决方案：
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:variable name="vDelims">\s*'\s*,?</xsl:variable>
<xsl:variable name="vTokens" select="tokenize(/*/@Icons, $vDelims)[.]"/>
<xsl:template match="/*">
<xsl:for-each select="$vTokens[position() le 3]">
<img src="{.}" alt=""/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
对以下XML文档应用此转换时：
<t Icons=
"'http://www.test.com/image1.jpg',
'http://www.test.com/image2.jpg',
'http://www.test.com/image3.jpg',
'http://www.test.com/image4.jpg',
'http://www.test.com/image5.jpg'"/>
产生了想要的正确结果：
<img src="http://www.test.com/image1.jpg" alt=""/>
<img src="http://www.test.com/image2.jpg" alt=""/>
<img src="http://www.test.com/image3.jpg" alt=""/>
答案 2 :(得分：0)
使用tokenize函数。在http://www.xml.com/pub/a/2003/05/07/tr.html有关于tokenize的好文章。 （OR）
使用此
<?xml version="1.0" standalone="yes"?>
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<xsl:variable name="v" select="data/text()"/>
<list>
<xsl:call-template name="parse">
<xsl:with-param name="in" select="normalize-space(translate($v,'[]',''))"/>
<xsl:with-param name="num">0</xsl:with-param>
</xsl:call-template>
</list>
</xsl:template>
<xsl:template name="parse">
<xsl:param name="in"/>
<xsl:param name="num"/>
<xsl:variable name="char">'</xsl:variable>
<xsl:if test="$num < 3">
<xsl:element name="image">
<xsl:attribute name="href"><xsl:value-of select="translate(substring-before($in,','),$char,'')"/></xsl:attribute>
</xsl:element>
<xsl:call-template name="parse">
<xsl:with-param name="in" select="substring-after($in,',')"/>
<xsl:with-param name="num"><xsl:value-of select="$num + 1"/></xsl:with-param>
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>