Question

我想知道为什么，但我不能简单地调试我的简单程序。忽略加载的方法，它永远不会被执行。不知道为什么。看：

    TGridObj = class (TComponent)
private
  FPen1:TPen;
  FBrush1:TBrush;
  FChange:TNotifyEvent;

protected
  procedure Loaded; override;


public
  constructor Create(AOwner: TComponent); override;
  destructor Destroy; override;
published
  property OnChange:TNotifyEvent read FChange write FChange;

  property Pen1:TPen read FPen1 write FPen1;
  property Brush1:TBrush read FBrush1 write FBrush1;
end;

。。

constructor TGridObj.Create(AOwner: TComponent);
  begin
  inherited Create(AOwner);
  FPen1:=TPen.Create;
  FPen1.OnChange:=FChange;


  FBrush1:=TBrush.Create;
  FBrush1.OnChange:=FChange;
  end;


destructor TGridObj.destroy;
  begin
  FPen1.Free;
  FBrush1.Free;
  inherited;
  end;

procedure TGridObj.Loaded();
begin
  inherited Loaded;
  ShowMessage('');   // this is never executed;
  FPen1.OnChange:=FChange;
  FBrush1.OnChange:=FChange;
end;

。

procedure TForm1.FormCreate(Sender: TObject);
begin
Grid:=TGridObj.Create(nil);
Grid.OnChange:=ev1.OnChange;
Form1.InsertComponent(Grid);
end;

感谢名单

Answer 1

仅当从表单文件流式传输组件的属性时，才会调用

Loaded。由于您是在运行时创建的，因此不会调用Loaded。这是设计的。

无论如何，您的代码需要一些工作才能在运行时修改OnChange事件，并将更改过滤到笔和画笔。我会这样做：

TGridObj = class (TComponent)
private
  FPen1: TPen;
  FBrush1: TBrush;
  FChange: TNotifyEvent;
  procedure DoChange(Sender: TObject);
public
  constructor Create(AOwner: TComponent); override;
  destructor Destroy; override;
published
  property OnChange: TNotifyEvent read FChange write FChange;
  property Pen1: TPen read FPen1;
  property Brush1: TBrush read FBrush1;
end;

constructor TGridObj.Create(AOwner: TComponent);
begin
  inherited;
  FPen1 := TPen.Create;
  FPen1.OnChange := DoChange;
  FBrush1 := TBrush.Create;
  FBrush1.OnChange := DoChange;
end;

destructor TGridObj.Destroy;
begin
  FBrush1.Free;
  FPen1.Free;
  inherited;
end;

procedure TGridObj.DoChange(Sender: TObject);
begin
  if Assigned(FChange) then
    FChange(Sender);
end;

现在不需要Loaded或类似的东西。因为您等到笔和笔刷的OnChange事件实际触发之后才会访问FChange。

顺便说一句，在代码中添加修改基础字段的Pen1和Brush1的属性设置器是错误的。这会导致泄漏和各种混乱。另外，请注意，将笔和画笔公开为公共属性允许TGridObj的客户更改OnChange事件。这颠覆了TGridObj.OnChange。

Answer 2

只有在从表单资源（dfm文件）加载组件时才会执行OnLoaded。

如果组件仅在代码中在运行时创建，则不会执行。

更新

我建议设计组件，以便在运行时也可以创建和配置它们 - 这意味着我可以避免覆盖OnLoaded。优点是不需要包安装/组件注册。

为什么加载方法被忽略？

2 个答案: