Question

我想要求用户输入密码。由于密码有时需要在与运行VCL的主线程不同的线程中，因此我尝试向主窗口发送消息并要求输入密码。然后主窗口会询问用户。

我如何询问用户：

procedure TMainForm.WMGetPassword(var Msg: TMessage);
var
  Password: String;
begin
  if QueryPassword(Password) then // function QueryPassword(out Password: String): boolean;
  begin
    Password := Password + #0; // Add #0-Terminator
    Move(Password[1], Msg.wParam, Length(Password) * sizeOf(Char)); // Copy the String in my buffer
    Msg.Result := 1;
  end
  else
  begin
    Msg.Result := 0;
  end;
end;

我如何询问主窗口：

var
  PasswordBuffer: PChar;
  Password: String;
begin
  PasswordBuffer := AllocMem(100 * sizeof(Char));
  PasswordResult := SendMessage(MainFormHWND, WM_GetPassword, Integer(PasswordBuffer), 0);
  Result := (PasswordResult <> -1);
  if not Result then
    Exit;

  SetString(Password, PasswordBuffer, 100);
  ShowMessage(Password);
end;

但Password和PasswordBuffer之后是空的。我做错了什么？

Answer 1

由于您将Msg.wParam作为第二个参数传递，因此它将您的字符串写入该位置，而不是您要指向的位置。它将覆盖存储在Msg.wParam，Msg.lParam，Msg.Result中的值以及堆栈上的其他一些信息。

而不是：

Move(Password[1], Msg.wParam, Length(Password) * sizeOf(Char));

您应该使用：

Move(Password[1], PChar(Msg.wParam)^, Length(Password) * sizeOf(Char));

如果你想使用指针，请使用MoveMemory。

Answer 2

只要线程处于同一进程（因此它共享相同的地址空间），您的代码就可以工作。然而，它不必要地复杂并且有内存泄漏（PasswordBuffer永远不会被释放）。

您可以在线程中使用字符串变量，并将地址传递给其内部预分配缓冲区到主线程：

type
  TTestThread = class(TThread)
  private
    fHwnd: HWND;
  protected
    procedure Execute; override;
  public
    constructor Create(AWnd: HWND);
  end;

constructor TTestThread.Create(AWnd: HWND);
begin
  fHwnd := AWnd;
  inherited Create(False);
end;

procedure TTestThread.Execute;
const
  MAXLEN = 1024;
var
  s: string;
begin
  SetLength(s, MAXLEN);
  if SendMessage(fHwnd, WM_GETPASSWORD, MAXLEN, LPARAM(@s[1])) > 0 then begin
    s := PChar(s);
    // don't use VCL here
    Windows.MessageBox(0, PChar('password is "' + s + '"'), 'password',
      MB_ICONINFORMATION or MB_OK);
  end;
end;

在主线程中，密码被放入缓冲区，长度限制为缓冲区大小：

procedure TForm1.WMGetPassword(var AMsg: TMessage);
var
  Pwd: string;
begin
  if InputQuery('Password Entry', 'Please enter the password:', Pwd)
    and (Pwd <> '')
  then begin
    StrPLCopy(PChar(AMsg.LParam), Pwd, AMsg.WParam);
    AMsg.Result := 1;
  end else
    AMsg.Result := -1;
end;

Answer 3

@Dan说得对，加上@mghie发现泄漏。

这是一种不涉及指针的替代方法：

type
  TMyMessage = class
    msg: string;
  end;

procedure TMainForm.WMGetPassword(var Msg: TMessage);
var
  SMessage: TMyMessage;
  Password: string;
begin
  if QueryPassword(Password) then 
  begin
    SMessage := TMyMessage(msg.WParam);
    SMessage.msg := Password;
    msg.Result := 1;
  end
  else
  begin
    Msg.Result := 0;
  end;
end;


var
  MyMsg: TMyMessage;
begin
  MyMsg := TMyMessage.Create('');
  try
    PasswordResult := SendMessage(FormHandleHWND,WM_GetPassword,WPARAM(MyMsg),0);
    Result := (PasswordResult <> -1);
    if Result
      then Password := MyMsg.msg;
  finally
    MyMsg.Free;
  end;
end;

询问用户并将消息发送回消息接收者

3 个答案: