Question

是否可以仅使用XSL转换匹配XML文档中第一次出现的值？

我想打印出f2中的每个值，但只打印f1内容的第一个实例。

XML数据

    <doc> 
    <datum>
        <f1>A</f1>
        <f2>Monday</f2>
      </datum>
      <datum>
        <f1>A</f1>
        <f2>Tuesday</f2>
      </datum>
      <datum>
        <f1>B</f1>
        <f2>Wednesday</f2>
    </datum>
    </doc>

输出

      A
      -Monday
      -Tuesday
      B
      -Wednesday

Answer 1

<强>予。这是XSLT 1.0着名的Muenchian Grouping method：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="kDatumByF1" match="datum" use="f1"/>

 <xsl:template match=
   "datum[generate-id() = generate-id(key('kDatumByF1', f1)[1])]">
   <xsl:value-of select="concat('&#xA;', f1)"/>
   <xsl:apply-templates select="key('kDatumByF1', f1)/f2" mode="inGroup"/>
 </xsl:template>

 <xsl:template match="f2" mode="inGroup">
   - <xsl:value-of select="."/>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<doc>
    <datum>
        <f1>A</f1>
        <f2>Monday</f2>
    </datum>
    <datum>
        <f1>A</f1>
        <f2>Tuesday</f2>
    </datum>
    <datum>
        <f1>B</f1>
        <f2>Wednesday</f2>
    </datum>
</doc>

产生了想要的正确结果：

A
   - Monday
   - Tuesday
B
   - Wednesday

<强> II。 XSLT 2.0解决方案，使用xsl:for-each-group

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

 <xsl:template match="/*">
     <xsl:for-each-group select="datum" group-by="f1">
     <xsl:sequence select="'&#xA;', f1"/>
     <xsl:apply-templates select="current-group()/f2"/>
     </xsl:for-each-group>
 </xsl:template>

  <xsl:template match="f2">
   - <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

使用XSLT可以防止连续相同值的输出吗？

1 个答案: