Question

为了创建生成器，你可以在 Mathematica 中做Python的yield语句吗？参见例如这个概念here。

更新这是我的意思的一个例子，迭代所有排列，仅使用O(n)空间:(在Sedgewick的算法书中算法）：

gen[f_, n_] := Module[{id = -1, val = Table[Null, {n}], visit},
  visit[k_] := Module[{t},
    id++; If[k != 0, val[[k]] = id];
    If[id == n, f[val]];
    Do[If[val[[t]] == Null, visit[t]], {t, 1, n}];
    id--; val[[k]] = Null;];
  visit[0];
  ]

然后把它称为：

gen[Print,3]，打印长度为3的所有6种排列。

Answer 1

正如我之前所说，使用Compile会得到更快的代码。使用fxtbook中的算法，以下代码以字典顺序生成下一个分区：

PermutationIterator[f_, n_Integer?Positive, nextFunc_] := 
 Module[{this = Range[n]},
  While[this =!= {-1}, f[this]; this = nextFunc[n, this]];]

以下代码假定我们运行版本8：

ClearAll[cfNextPartition];
cfNextPartition[target : "MVM" | "C"] := 
  cfNextPartition[target] = 
   Compile[{{n, _Integer}, {this, _Integer, 1}},
    Module[{i = n, j = n, ni, next = this, r, s},
     While[Part[next, --i] > Part[next, i + 1], 
      If[i == 1, i = 0; Break[]]];
     If[i == 0, {-1}, ni = Part[next, i]; 
      While[ni > Part[next, j], --j];
      next[[i]] = Part[next, j]; next[[j]] = ni;
      r = n; s = i + 1;
      While[r > s, ni = Part[next, r]; next[[r]] = Part[next, s]; 
       next[[s]] = ni; --r; ++s];
      next
      ]], RuntimeOptions -> "Speed", CompilationTarget -> target
    ];

然后

In[75]:= Reap[PermutationIterator[Sow, 4, cfNextPartition["C"]]][[2, 
   1]] === Permutations[Range[4]]

Out[75]= True

这在性能上明显优于原始gen函数。

In[83]:= gen[dummy, 9] // Timing

Out[83]= {26.067, Null}

In[84]:= PermutationIterator[dummy, 9, cfNextPartition["C"]] // Timing

Out[84]= {1.03, Null}

使用Mathematica的虚拟机速度并不慢：

In[85]:= PermutationIterator[dummy, 9, 
  cfNextPartition["MVM"]] // Timing

Out[85]= {1.154, Null}

当然，这远不及C代码实现，但却比纯顶级代码提供了显着的加速。

Answer 2

你可能意味着问题要更加通用，但是你链接到的页面上给出的迭代迭代的例子恰好是内置在Mathematica中的：

Scan[Print, Permutations[{1, 2, 3}]]

Print可以替换为任何功能。

Mathematica的产量

2 个答案: