Question

以下效果很好（感谢这个社区的亲切帮助！）

    Function RangeToArrayToRange(inputRange as Range) As Variant
            Dim inputArray As Variant
            inputArray = inputRange
            RangeToArrayToRange = inputArray
    End Function

此功能可将输入范围完美复制到输出。但是，当我对inputArray执行某些操作时，数组看起来很完美，但在Excel中，只有数组的第一个值打印到所有单元格。在这个例子中，我从一些输入字符串中解析出一个数字。

输入范围：

ABC=1X:2Y 
ABCD=10X:20Y
ABCDE=100X:200Y

代码：

    Function RangeToArrayToRange(inputRange As Range) As Variant

        Dim inputHeight As Integer
        inputHeight = inputRange.Count

        Dim inputArray As Variant
        inputArray = inputRange

        Dim strippedArray() As Variant
        ReDim strippedArray(1 To inputHeight)

        Dim currentInput As String
        Dim currentInputAsInt As Integer
        Dim i As Integer

        For i = 1 To inputHeight

            currentInput = inputArray(i, 1)
            currentInput = Right(currentInput, (Len(currentInput) - Application.WorksheetFunction.Find("=", currentInput))) 
            'splits out everything left of the "="
            currentInput = Right(currentInput, (Len(currentInput) - Application.WorksheetFunction.Find(":", currentInput)))
            'splits out everything to the right of the ":"
            currentInput = Left(currentInput, Len(currentInput) - 1) 
            'split out the letter to allow int casting
            currentInputAsInt = CInt(currentInput)
            'cast to int
            strippedArray(i) = currentInputAsInt
            'saved

        Next i

        RangeToArrayToRange = strippedArray
    End Function

预期产出：

1
10
100

实际输出：

1
1
1

使用调试器运行，strippedArray分别在位置strippedArray（1）/（2）/（3）处包含Variant / Integer值1,10,100。问题是我在Excel中输入的范围只包含strippedArray（1），据我所知。

谢谢！

Answer 1

如果要输出回Excel工作表/范围，那么您的strippedArray数组需要是二维的（我假设您将其作为数组公式运行）。进行以下更改：

ReDim strippedArray(1 To inputHeight, 1 To 1)
...
strippedArray(i, 1) = currentInputAsInt

VBA UDF Variant / Integer和Variant / String Arrays仅打印输出单元格的第一个值

1 个答案: