Question

使用XSL 1.0，我发现了一个很好的tokenize函数。现在我需要在结果标记上进行每次操作。我是XSL的新手。

PHP相当于我需要的东西：

$in = 'a,b,c,d';
$tokens = explode (',', $in);
foreach ($tokens as $token) {
  echo $token;
}

这是我到目前为止所拥有的。该行将输出'a，b，c，d' -

<xsl:value-of select="@CommaSeparated" />

这将通过tokenize函数运行该字符串 -

  <xsl:call-template name="tokenize">
    <xsl:with-param name="pText" select="@CommaSeparated"/>
  </xsl:call-template>

以及tokenize函数。我理解这是做什么的，而不是它吐出的数据的格式 -

<xsl:template name="tokenize">
  <xsl:param name="pText"/>

  <xsl:if test="string-length($pText)">
    <tag>
      <xsl:value-of select=
       "substring-before($pText, ',')"/>
    </tag>

    <xsl:call-template name="tokenize">
      <xsl:with-param name="pText" select=
       "substring-after($pText, ',')"/>
    </xsl:call-template>
  </xsl:if>
</xsl:template>

Answer 1

首先，使用的tokenize函数实际上并不正确。从理论上讲，它应该吐出一个标签元素列表（严格来说就是“结果树片段”），如此

<tag>a</tag>
<tag>b</tag>
<tag>c</tag>
<tag>d</tag>

但它实际上错过了最后一个元素

<tag>a</tag>
<tag>b</tag>
<tag>c</tag>
<tag></tag>

你可能最好在这里找到另一个tokenize函数（在StackOverflow中肯定有工作的那个）。

但是，在回答你关于使用xsl：for-each的问题时，你可能会想做这样的事情......

  <xsl:variable name="tags">
    <xsl:call-template name="tokenize">
       <xsl:with-param name="pText" select="@CommaSeparated"/>
     </xsl:call-template> 
  </xsl:variable>

  <xsl:for-each select="$tags/tag">
     <xsl:copy-of select="." />
  </xsl:for-each>

也就是说，将标记列表存储在变量中，然后循环遍历它们。但是，如果在XSLT1.0中尝试此操作，则会出现错误“表达式必须计算到节点集”。要解决这个问题，您需要使用扩展功能。 EXSLT可能是最常见的。您可以在XSLT中声明这个，如此

<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:exsl="http://exslt.org/common" 
    exclude-result-prefixes="exsl">

您可以按照以下方式更改 xsl：for-each ：

<xsl:for-each select="exsl:node-set($tags)/tag">

所以，给定以下XML

<a CommaSeparated="a,b,c,d"></a>

以下XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:exsl="http://exslt.org/common" exclude-result-prefixes="exsl">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/a">
        <xsl:variable name="tags">
            <xsl:call-template name="tokenize">
                <xsl:with-param name="pText" select="@CommaSeparated"/>
            </xsl:call-template>
        </xsl:variable>
        <xsl:for-each select="exsl:node-set($tags)/tag">
            <xsl:copy-of select="."/>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="tokenize">
        <xsl:param name="pText"/>
        <xsl:if test="string-length($pText)">
            <tag>
                <xsl:value-of select="substring-before($pText, ',')"/>
            </tag>
            <xsl:call-template name="tokenize">
                <xsl:with-param name="pText" select="substring-after($pText, ',')"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

输出以下内容（由于您正在使用的标记缩放功能，最后一个标记为空白）

<tag>a</tag>
<tag>b</tag>
<tag>c</tag>
<tag></tag>

Answer 2

检查此代码：

<xsl:variable name="val">
       <xsl:value-of select="@CommaSeparated"/><xsl:text disable-output-escaping="yes"><![CDATA[ ]]></xsl:text>
</xsl:variable>

<xsl:template match="/a">
    <xsl:variable name="tags">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="pText" select="$val"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:for-each select="exsl:node-set($tags)/tag">
        <xsl:copy-of select="."/>
    </xsl:for-each>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="pText"/>
    <xsl:if test="string-length($pText)">
        <tag>
            <xsl:value-of select="substring-before($pText, ',')"/>
        </tag>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="pText" select="substring-after($pText, ',')"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

XSL 1.0 - 如何在标记化字符串上使用for-each

2 个答案: