Question

是否可以编写单个模板化函数来递增不同结构的（数字）字段？例如：

struct Color
{
    ubyte a,r,g,b;
}

struct Point
{
    double x, y;
}

我试过这样的事情：

T update(T, A)(T t, A a)
if (is(T == struct))
{
    auto vals = t.tupleof;
    foreach (i; 0 .. vals.length) {
        vals[i] += a; // error: i cannot be read at compile time
    }
    return T(vals); // convert back to struct
}

我也尝试编写接受元组的函数模板，但是元组总是被扩展，这会阻止编译器匹配正确的模板。感谢。

Answer 1

好吧，我会说你正在尝试的事情是相当奇怪的，但它肯定是可能的。最天真的，就地方式可能是：

void update(T)(ref T t)
    if(is(T == struct))
{
    foreach(ref var; t.tupleof)
        ++var;
}

使用副本执行此操作的最简单方法可能是复制它然后更新它而不是尝试构建具有更新值的新程序（尽管我确信如果您真的想要这样做也可以）：

T update(T)(T t)
    if(is(T == struct))
{
    auto copy = t;

    foreach(ref var; copy.tupleof)
        ++var;

    return copy;
}

当然，这里的主要问题是两者的模板约束都太弱了。您所要做的就是在结构中使用不可增量的类型，它将无法工作。解决这个问题的最简单方法可能是创建一个同名模板来为您测试它：

T update(T)(T t)
    if(isIncrementableStruct!T)
{
    auto copy = t;

    foreach(ref var; copy.tupleof)
        ++var;

    return copy;
}

template isIncrementableStruct(T)
{
    enum isIncrementableStruct = is(T == struct) &&
                                 is(typeof({T t; foreach(var; t.tupleof) ++var;}));
}

如果您希望能够递增所有可递增的字段并让其他字段保持不变，那么您可能会执行以下操作：

T update(T)(T t)
    if(is(T == struct))
{
    auto copy = t;

    foreach(ref var; copy.tupleof)
    {
        static if(canIncrement!(typeof(var)))
            ++var;
    }

    return copy;
}

template canIncrement(T)
{
    enum canIncrement = is(typeof({T var; ++var;}));
}

在任何情况下，您似乎错过的主要事情是在使用tupleof时尝试直接迭代ref，以便更新元素而不是更新它们的副本。< / p>

D中的Struct和Tuple模板参数

1 个答案: