Question

我正在尝试在校对检查器中定义一个域。我该怎么做？

我正在尝试相当于V in [0,10]。

我尝试Definition V := forall v in R, 0 <= v /\ v <= 10.，但这会导致像0这样的常量问题根据Coq不在V。

Answer 1

一种简单的方法可能是，

Require Import Omega.

Inductive V : Set :=
  mkV : forall (v:nat), 0 <= v /\ v <= 10 -> V.

Lemma member0 : V.
Proof. apply (mkV 0). omega. Qed.

Definition inc (v:V) : nat := match v with mkV n _ => n + 1 end.

Lemma inc_bounds : forall v, 0 <= inc v <= 11.
Proof. intros v; destruct v; simpl. omega. Qed.

当然member0的类型可能没有您想要的那样丰富。在这种情况下，您可能希望通过与该集合中每个元素对应的V索引nat。

Require Import Omega.

Inductive V : nat -> Set :=
  mkV : forall (v:nat), 0 <= v /\ v <= 10 -> V v.

Lemma member0 : V 0.
Proof. apply (mkV 0). omega. Qed.

Definition inc {n} (v:V n) : nat := n + 1.

Lemma inc_bounds : forall {n:nat} (v:V n), 0 <= inc v <= 11.
Proof. intros n v. unfold inc. destruct v. omega. Qed.

之前我没有使用Reals，但上述内容也可以在R上实施。

Require Import Reals.
Require Import Fourier.
Open Scope R_scope.

Inductive V : R -> Set :=
  mkV : forall (v:R), 0 <= v /\ v <= 10 -> V v.

Lemma member0 : V 0.
Proof. apply (mkV 0). split. right; auto. left; fourier. Qed.

Definition inc {r} (v:V r) : R := r + 1.

Lemma inc_bounds : forall {r:R} (v:V r), 0 <= inc v <= 11.
Proof. intros r v; unfold inc. 
  destruct v as (r,pf). destruct pf. split; fourier. 
Qed.

Answer 2

我相信这样做的自然方式是使用sig类型，Yves在评论中也提到过。

V的元素将是来自R的数字x，以及证明它们确实应该在集合V中的证据。

Require Import Reals Fourier.
Open Scope R_scope.

Definition V_prop (x : R) : Prop := 0 <= x /\ x <= 10.

Definition V : Set := { x : R | V_prop x }.

Lemma V_prop0: V_prop 0.
Proof.
    unfold V_prop; split;
    [right; auto | left; fourier].
Qed.

Definition V0 : V := exist _ 0 V_prop0.

如何在coq中定义有限域

2 个答案: