Cython和c ++类构造函数

Question

有人建议使用Cython来操作c ++对象的方法 期望一个类的c ++实例提供另一个包的构造函数 课程如下所述？

请查看PySession类的pyx文件中的注释 将python PyConfigParams对象作为参数然后需要 从中提取值以构造c ++ ConfigParams 宾语。然后使用ConfigParams对象来提供构造函数 会议。

有一个允许我“注射”的程序是理想的 由PyConfigParams对象包装的ConfigParams c ++对象 直接进入Session的构造函数，而不必拆除 首先，然后构建一个新的c ++对象来提供构造函数。 当然，这是有效的。然而，实施这种解决方案是一种繁琐，残酷的方式，更不用说不可靠了。

我知道PyCapsule，但它可能需要触摸c ++标题，这是我不能做的。

与此相关，但另一个问题是：如果我需要包装，该怎么办？ class（比如说PySession）来模拟C ++的行为 api通过返回ConfigParams实例？我需要做的吗？ 反转并拆除c ++对象以构建Python PyConfigParams 然后将返回Python世界中的Python用户？ 任何建议都非常欢迎！ 谢谢！

假设我有两个名为ConfigParams和Session的c ++类。 ConfigParams的一个实例用于提供构造函数 会话类：

C ++类

ConfigParams类

// ConfigParams.h
#include <iostream> 
using namespace std; 
class ConfigParams 
{ 
  int parameter1; 
 public: 
  ConfigParams(int par1) { this->parameter1 = par1;} 
  int getPar1() { return this->parameter1; } 
};

会话类

// Session.h 
#include <iostream> 
using namespace std; 
#include "configparams.h" 
class Session 
{ 
  int sessionX; 
 public: 
  Session(ConfigParams parameters) { this->sessionX = parameters.getPar1(); } 
  void doSomething(); 
}; 

void Session::doSomething() 
{ 
  cout << "Session parameters set as: " << endl; 
  cout << "X = " << this->sessionX << endl; 
} 

上述类的Cython pyx和pxd文件：

PyConfigParams

# configparams.pxd 
cdef extern from "configparams.h": 
    cppclass ConfigParams: 
        ConfigParams(int par1) 
        int getPar1() 

# configparams.pyx 
cdef class PyConfigParams: 
    cdef ConfigParams* thisptr 
    def __cinit__(self, i): 
        self.thisptr = new ConfigParams(<int> i) 
    def getPar1(self): 
        return self.thisptr.getPar1() 

PySession类

# session.pxd 
from configparams cimport * 
cdef extern from "session.h": 
    cdef cppclass Session: 
        Session(ConfigParams parameters) 
        void doSomething() 

# session.pyx
cdef class PySession: 
    cdef Session* thisptr 
    def __cinit__(self, pars): 
        # Note that here I have to extract the values 
        # from the pars (python PyConfigParams object) 
        # in order to build a c++ ConfigParams object 
        # which feeds the c ++ constructor of Session. 
        cdef ConfigParams* cpppargsptr = new ConfigParams(<int> pars.getPar1()) 
        self.thisptr = new Session(cpppargsptr[0]) 
    def doSomething(self): 
        self.thisptr.doSomething() 

Answer 1

解决方案：

在configparams.pxd模块中转发声明PyConfigParams（因此可以从session.pyx模块调用它）

# configparams.pxd                                                                                                                                                                                                                                            
cdef extern from "configparams.h":
    cppclass ConfigParams:
        ConfigParams(int par1)
        int getPar1()

cdef class PyConfigParams:
    cdef ConfigParams* thisptr

在session.pyx模块中导入PyConfigParams，并为constuctor转换参数，这将授予对c ++对象的PyConfigParams指针的访问权限，该指针需要被解引用。

# session.pyx                                                                                                                                                                                                                                                 
from configparams cimport PyConfigParams
from cython.operator cimport dereference as deref

cdef class PySession:
    cdef Session* thisptr
    def __cinit__(self, PyConfigParams pars):
        self.thisptr = new Session(deref(pars.thisptr))
    def doSomething(self):
        self.thisptr.doSomething()