Question

您好我需要用逗号分隔日期并添加新数据。

<fields>
<field name="example"><value>example,i,am,new,to,xslt</value></field>
<fields>

我需要将此xml转换为

<fields>
<field name="example"><value>example</value><value>i</value>am</value><value>new</value><value>to</value><value>xslt</value></field>
<fields>

任何人都可以解释如何使用XSLT

来做到这一点

Answer 1

<强>予。 XSLT 2.0解决方案：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="value">
   <xsl:for-each select="tokenize(., ',')">
     <value><xsl:value-of select="."/></value>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时（已更正!!!!以确保格式良好）：

<fields>
    <field name="example">
        <value>example,i,am,new,to,xslt</value>
    </field>
</fields>

产生了想要的正确结果：

<fields>
   <field name="example">
      <value>example</value>
      <value>i</value>
      <value>am</value>
      <value>new</value>
      <value>to</value>
      <value>xslt</value>
   </field>
</fields>

<强> II。 XSLT 1.0解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="value" name="tokenize">
  <xsl:param name="pText" select="."/>

  <xsl:if test="string($pText)">
   <value>
    <xsl:value-of select=
     "substring-before(concat($pText, ','), ',')"/>
   </value>

   <xsl:call-template name="tokenize">
     <xsl:with-param name="pText" select=
        "substring-after($pText, ',')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于同一XML文档（上图）时，会生成相同的正确结果：

<fields>
   <field name="example">
      <value>example</value>
      <value>i</value>
      <value>am</value>
      <value>new</value>
      <value>to</value>
      <value>xslt</value>
   </field>
</fields>

<强>解释：

使用身份规则“按原样”复制所有内容。
覆盖（{1}}匹配的（身份模板）模板。
在解决方案I中 - 正确使用标准XPath 2.0函数value。
在解决方案II中 - 实现某些东西使用命名模板来运行tokenize()函数 - 因为XPath 1.0 / XSLT 1.0中没有定义tokenize()。
在方便II中，为方便起见，我们将匹配tokenize()的模板与执行逗号标记的命名模板合并。

使用命令在xsl中创建新字段来分隔数据

1 个答案: