Question

一个事务可以以原子方式更新两个不同的TVar吗？即，我可以从许多TVar中组合数据结构以减少争用吗？如果是这样，你能提供一个例子吗？

Answer 1

一个事务可以原子方式更新两个不同的电视剧吗？

是的，您可以在一次交易中以原子方式更新多个TVars。这就是STM的重点。如果你做不到，那就没用了。

我可以从许多电视剧中组合数据结构以减少争用吗？如果是这样，你能提供一个例子吗？

这是在数据结构中存储TVars的（有点愚蠢）示例。它模拟了银行账户之间的一堆随机并发交易，每个账户只有一个TVar Integer。帐户电视广告保存在帐户ID的地图中，帐户ID本身保存在电视中，以便可以即时创建新帐户。

import Control.Concurrent
import Control.Concurrent.MVar
import Control.Concurrent.STM
import Control.Monad
import System.Random

import qualified Data.Map as Map

type AccountId = Int
type Account = TVar Dollars
type Dollars = Integer
type Bank = TVar (Map.Map AccountId Account)

numberOfAccounts = 20
threads = 100
transactionsPerThread = 100
maxAmount = 1000

-- Get account by ID, create new empty account if it didn't exist
getAccount :: Bank -> AccountId -> STM Account
getAccount bank accountId = do
  accounts <- readTVar bank
  case Map.lookup accountId accounts of
    Just account -> return account
    Nothing -> do
      account <- newTVar 0
      writeTVar bank $ Map.insert accountId account accounts
      return account

-- Transfer amount between two accounts (accounts can go negative)
transfer :: Dollars -> Account -> Account -> STM ()
transfer amount from to = when (from /= to) $ do
  balanceFrom <- readTVar from
  balanceTo <- readTVar to
  writeTVar from $! balanceFrom - amount
  writeTVar to $! balanceTo + amount

randomTransaction :: Bank -> IO ()
randomTransaction bank = do
  -- Make a random transaction
  fromId <- randomRIO (1, numberOfAccounts)
  toId   <- randomRIO (1, numberOfAccounts)
  amount <- randomRIO (1, maxAmount)

  -- Perform it atomically
  atomically $ do
    from <- getAccount bank fromId
    to   <- getAccount bank toId
    transfer amount from to

main = do
  bank <- newTVarIO Map.empty

  -- Start some worker threads to each do a number of random transactions
  workers <- replicateM threads $ do
    done <- newEmptyMVar
    forkIO $ do
      replicateM_ transactionsPerThread $ randomTransaction bank
      putMVar done ()
    return done

  -- Wait for worker threads to finish
  mapM_ takeMVar workers

  -- Print list of accounts and total bank balance (which should be zero)
  summary <- atomically $ do
    accounts <- readTVar bank
    forM (Map.assocs accounts) $ \(accountId, account) -> do
      balance <- readTVar account
      return (accountId, balance)

  mapM_ print summary
  putStrLn "----------------"
  putStrLn $ "TOTAL BALANCE: " ++ show (sum $ map snd summary)

如果在转会期间没有竞争条件，这应该在最后打印总余额为零。

Answer 2

交易完全是原子的;如果它修改了多个TVar，则两个更改将一起发生，原子地，孤立地发生。在单个atomically块中运行的任何操作都是单个事务。例如：

swap :: (Num a) => TVar a -> TVar a -> STM ()
swap v1 v2 = do
    a <- readTVar v1
    b <- readTVar v2
    writeTVar v1 b
    writeTVar v2 a

在这里，swap a b将原子地交换两个TVar。以这种方式进行原子事务的可组合性是STM的主要优点之一。

Haskell：原子地更新两个或更多TVar。可能？

2 个答案: