Question

我可以在穆斯这样做吗？

package SomeClass;
use Moose;

has start => (
    isa => 'Int',
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->end },
);

has end => (
    isa => 'Int',
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->start },
);

...

换句话说，我想要两个名为“start”和“end”的属性，如果只指定了其中一个属性，我希望将另一个属性设置为相同的东西。没有指定任何一个是错误。

这种相互依赖的设置是否有效？

Answer 1

是的， if 通过验证至少指定了其中一个值来消除无限递归的可能性：

has start => (
    ...
    predicate => 'has_start',
);

has end => (
    ...
    predicate => 'has_end',
);

sub BUILD
{
    my $self = shift;

    die "Need to specify at least one of 'start', 'end'!" if not $self->has_start and not $self->has_end;
}

或者，您可以将检查延迟到默认的潜艇：

has start => (
    ...
    predicate => 'has_start',
    default => sub {
        my $self = shift;
        die "Need to specify at least one of 'start', 'end'!" if not $self->has_end;
        $self->end;
    },
);

has end => (
    ...
    predicate => 'has_end',
    default => sub {
        my $self = shift;
        die "Need to specify at least one of 'start', 'end'!" if not $self->has_start;
        $self->start;
    },
);

Answer 2

就个人而言，我会利用懒惰来确保我没有陷入无限递归：

has start => (
  is => 'ro',
  isa => 'Int',
  lazy => 1,
  default => sub { shift->end },
  predicate => 'has_start',
);

has end => (
  is => 'ro',
  isa => 'Int',
  lazy => 1,
  default => sub { shift->start },
  predicate => 'has_end',
);

sub BUILD {
  my $self = shift;

  die "Need to specify at least one of 'start', 'end'!" 
    unless $self->has_start || $self->has_end;
}

在Perl / Moose中，我可以使用两个具有相互依赖的默认值的属性吗？

2 个答案: