Question

我有一个动态库，根据配置获取不同的名称，在CMake脚本中通过以下方式指定：

set_target_properties(${name} PROPERTIES OUTPUT_NAME ${outputName}64)
set_target_properties(${name} PROPERTIES DEBUG_OUTPUT_NAME ${outputName}64_d)

最终结果是我在发布和调试版本上获得了不同的名称。我想将生成的库复制到不同的目录作为构建后的步骤，但是CMake-Fu的礼物（？）并没有真正对你微笑。

我试过这样做：

GET_TARGET_PROPERTY(origfile mylibrary LOCATION)
STRING(REGEX REPLACE "/" "\\\\" origfile ${origfile})

set(targetfile my_target_path\\${CMAKE_CFG_INTDIR}\\)
STRING(REGEX REPLACE "/" "\\\\" targetfile ${targetfile})

add_custom_command(TARGET mylibrary POST_BUILD
    COMMAND copy ${origfile} ${targetfile}
)

这适用于发布版本，但是对于调试，源代码不包含我期望的_d。 如何获取目标的输出路径以便我可以复制文件？

注意：从上面的代码片段可以看出，目前这是针对Windows / Visual Studio的，但我希望这也适用于OS X / Xcode / make。

注意：我需要将库放在一个额外的目录中，该目录充当依赖于此库的其他几个项目的输出目录，以便这些项目能够加载库运行。可接受的替代解决方案是能够创建执行复制的自定义目标，以便其他项目可以依赖于此项目，而该项目又取决于库。

Answer 1

不是使用过时的LOCATION属性，而是更喜欢使用生成器表达式：

add_custom_command(TARGET mylibrary POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:mylibrary> ${targetfile}
)

您也可以直接通过设置目标属性RUNTIME_OUTPUT_DIRECTORY而不是复制它来在目标目录中生成exe。这有每个配置选项（例如RUNTIME_OUTPUT_DIRECTORY_DEBUG）。

set_target_properties(mylibrary PROPERTIES
                      RUNTIME_OUTPUT_DIRECTORY_DEBUG <debug path>
                      RUNTIME_OUTPUT_DIRECTORY_RELEASE <release path>
)

有关详细信息，请运行：

cmake --help-property "RUNTIME_OUTPUT_DIRECTORY"
cmake --help-property "RUNTIME_OUTPUT_DIRECTORY_<CONFIG>"

此外，您应该能够在路径分隔符中使用正斜杠，即使在Windows上也是如此。

Answer 2

在POST_BUILD命令中使用generator expressions，而不是手动计算输出路径。这些是配置感知。例如：

add_custom_command(TARGET mylibrary POST_BUILD 
  COMMAND "${CMAKE_COMMAND}" -E copy 
     "$<TARGET_FILE:mylibrary>"
     "my_target_path/$<CONFIGURATION>/$<TARGET_FILE_NAME:mylibrary>" 
  COMMENT "Copying to output directory")

Answer 3

我对其他答案还不是100％清楚...

假设您正在构建可执行文件test_base.exe，以下将构建可执行文件，然后将.exe复制到基本的“ build”目录：

add_executable(test_base "")
target_sources(test_base
    PRIVATE
        catch_main.cpp
        catch_tests.cpp
        sc_main.cpp
)
target_link_libraries(test_base PRIVATE Catch2 systemc)

add_custom_command(TARGET test_base POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:test_base> ${PROJECT_BINARY_DIR}/test_base.exe
    COMMENT "Created ${PROJECT_BINARY_DIR}/test_base.exe"
)

因此，在运行之后，您的项目将具有：

<project dir>/build/test_base.exe

将目标文件复制到CMake中的后期构建步骤中的另一个位置

3 个答案: