TSplitter中的自定义绘制方法不使用Vcl样式颜色

Question

我正在使用此链接TSplitter enhanced with grab bar中发布的代码，在分割器控件中绘制一个抓取栏，

procedure TSplitter.Paint;
var
  R: TRect;
  X, Y: integer;
  DX, DY: integer;
  i: integer;
  Brush: TBitmap;
begin
  R := ClientRect;
  Canvas.Brush.Color := Color;
  Canvas.FillRect(ClientRect);

  X := (R.Left+R.Right) div 2;
  Y := (R.Top+R.Bottom) div 2;
  if (Align in [alLeft, alRight]) then
  begin
    DX := 0;
    DY := 3;
  end else
  begin
    DX := 3;
    DY := 0;
  end;
  dec(X, DX*2);
  dec(Y, DY*2);

  Brush := TBitmap.Create;
  try
    Brush.SetSize(2, 2);
    Brush.Canvas.Brush.Color := clBtnHighlight;
    Brush.Canvas.FillRect(Rect(0,0,1,1));
    Brush.Canvas.Pixels[0, 0] := clBtnShadow;
    for i := 0 to 4 do
    begin
      Canvas.Draw(X, Y, Brush);
      inc(X, DX);
      inc(Y, DY);
    end;
  finally
    Brush.Free;
  end;

end;

代码运行良好，但是当我启用vcl样式时，用于绘制分割器和抓取条的颜色不适合vcl样式使用。

如何使用当前主题的Vcl样式颜色绘制TSplitter？

Answer 1

使用代码的system color constants（clBtnFace，clBtnHighlight，clBtnShadow）不存储vcl样式颜色，必须使用StyleServices.GetSystemColor函数将这些颜色转换为vcl样式颜色。

procedure TSplitter.Paint;
var
  R: TRect;
  X, Y: integer;
  DX, DY: integer;
  i: integer;
  Brush: TBitmap;
begin
  R := ClientRect;
  if TStyleManager.IsCustomStyleActive then
    Canvas.Brush.Color := StyleServices.GetSystemColor(clBtnFace)
  else
  Canvas.Brush.Color := Color;

  Canvas.FillRect(ClientRect);

  X := (R.Left+R.Right) div 2;
  Y := (R.Top+R.Bottom) div 2;
  if (Align in [alLeft, alRight]) then
  begin
    DX := 0;
    DY := 3;
  end else
  begin
    DX := 3;
    DY := 0;
  end;
  dec(X, DX*2);
  dec(Y, DY*2);

  Brush := TBitmap.Create;
  try
    Brush.SetSize(2, 2);

    if TStyleManager.IsCustomStyleActive then
      Brush.Canvas.Brush.Color := StyleServices.GetSystemColor(clBtnHighlight)
    else
      Brush.Canvas.Brush.Color := clBtnHighlight;

    Brush.Canvas.FillRect(Rect(0, 0, Brush.Height, Brush.Width));

    if TStyleManager.IsCustomStyleActive then
      Brush.Canvas.Pixels[0, 0] :=  StyleServices.GetSystemColor(clBtnShadow)
    else
      Brush.Canvas.Pixels[0, 0] :=  clBtnShadow;

    for i := 0 to 4 do
    begin
      Canvas.Draw(X, Y, Brush);
      inc(X, DX);
      inc(Y, DY);
    end;
  finally
    Brush.Free;
  end;

end;