Question

我有一个带有Module和Userform的VBA项目。我想在我的Userform中使用模块中的一些变量。

我是否有必要全局声明这些变量？我不喜欢全局变量，因为它们在代码执行后留在内存中，我必须在宏的开头逐个重置这些变量。我不能使用关键字End来清除内存中的变量，因为我需要记住这些变量中的一个或两个。人们通常如何做？

编辑：有没有办法将变量从Userform传递给模块而不创建全局变量？

Answer 1

在您的用户表单中创建一个公共属性，并使用该属性将该变量传递给表单。 Useforms只是类模块，除了它们有一个用户界面组件。示例：在用户表单的代码模块中

Option Explicit

Private msLocalVar As String

Public Property Get LocalVar() As String
    LocalVar = msLocalVar
End Property

Public Property Let LocalVar(sLocalVar As String)
    msLocalVar = sLocalVar
End Property

Private Sub CommandButton1_Click()

    Me.LocalVar = Me.LocalVar & " more strings attached"

    Me.Hide

End Sub

在标准模块中

Sub ShowForm()

    Dim sLocalVar As String
    Dim ufUserForm1 As UserForm1

    sLocalVar = "Some string"

    Set ufUserForm1 = New UserForm1
    ufUserForm1.LocalVar = sLocalVar 'pass in variable
    ufUserForm1.Show

    'This executes after the .Hide in the form
    Debug.Print ufUserForm1.LocalVar

    'Close out the form - previously just hidden
    Unload ufUserForm1

End Sub

Answer 2

您可以这样做的一种方法是声明这样的公共变量：

Public strvar as String
Sub Abfrage()
'Your Code
End Sub

但是如果您不喜欢这种方式，可以插入一个新的Excel工作表，将新工作表的属性设置为“2 - xlSheetVeryHidden”，然后您可以在该工作表的单元格中写入您的值并将其读入来自您的UserForm。

因此，您将没有全局变量，但所有值都在该表上。然后，如果需要，您可以从该表中取出值。

有没有办法在模块之间使用局部变量？

2 个答案: