Question

我需要获取有关外部应用程序的Webbrowser控件的滚动条（位置，大小，可见性）的信息，我尝试使用之前GetScrollBarInfo中的question函数，但是函数总是返回false，我用另一个应用程序检查了这个函数并且运行正常，但是没有使用IE或Webbrowser控件。 So how I can get information about the scrollbars of an Webbrowser control instance or the IE Webbrowser?

Answer 1

您可以将WM_HTML_GETOBJECT消息发送到外部应用程序的"Internet Explorer_Server"类窗口以获取IHtmlDocument2，然后使用IServiceProvider获取IWebBrowser2接口。<登记/> 以下是Delphi中的一些示例代码：

uses
  ActiveX, MSHTML;

type
  TObjectFromLResult = function(LRESULT: lResult; const IID: TIID;
    wParam: wParam; out pObject): HRESULT; stdcall;

function GetIEFromHWND(WHandle: HWND; var IE: IWebbrowser2): HRESULT;
var
  hInst: HWND;
  lRes: Cardinal;
  Msg: Integer;
  pDoc: IHTMLDocument2;
  ObjectFromLresult: TObjectFromLresult;
begin
  Result := S_FALSE;
  hInst := LoadLibrary('Oleacc.dll');
  @ObjectFromLresult := GetProcAddress(hInst, 'ObjectFromLresult');
  if @ObjectFromLresult <> nil then
  try
    Msg := RegisterWindowMessage('WM_HTML_GETOBJECT');
    SendMessageTimeOut(WHandle, Msg, 0, 0, SMTO_ABORTIFHUNG, 1000, lRes);
    Result := ObjectFromLresult(lRes, IHTMLDocument2, 0, pDoc);
    if Result = S_OK then
      (pDoc.parentWindow as IServiceprovider).QueryService(
        IWebbrowserApp, IWebbrowser2, IE);
  finally
    FreeLibrary(hInst);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Wnd, WndChild: HWND;
  IE: IWebBrowser2;
  Document: IHtmlDocument2;
  ScrollTop, ScrollLeft: Integer;
begin
  Wnd := FindWindow('IEFrame', nil); // top level IE
  if Wnd = 0 then Exit;
  WndChild := FindWindowEX(Wnd, 0, 'Shell DocObject View', nil);
  if WndChild = 0 then Exit;
  WndChild := FindWindowEX(WndChild, 0, 'Internet Explorer_Server', nil);
  if WndChild = 0 then Exit;

  GetIEFromHWnd(WndChild, IE);
  if IE <> nil then
  begin
    ShowMessage(IE.LocationURL);
    Document := IE.Document as IHtmlDocument2;
    ScrollTop := ((Document as IHTMLDocument3).documentElement as IHTMLElement2).scrollTop;
    ScrollLeft := ((Document as IHTMLDocument3).documentElement as IHTMLElement2).scrollLeft;
    ShowMessage(Format('%d;%d', [ScrollTop, ScrollLeft]));

    // visible|hidden|scroll|auto|no-display|no-content
    ShowMessage(OleVariant(Document).documentElement.currentStyle.overflowX);
    ShowMessage(OleVariant(Document).documentElement.currentStyle.overflowY);
  end;
end;

当页面使用<!DOCTYPE>指令将IE6切换为严格时，

编辑符合标准的模式使用document.documentElement。（IHTMLDocument3）在预标准模式下，身体代表了可滚动区域，因此您可以检索滚动位置 document.body.scrollTop。在标准模式下，HTML元素是可滚动的，所以你应该使用document.documentElement.scrollTop。

如果document.documentElement.clientWidth <> 0使用documentElement元素作为属性，请使用body元素。
与滚动信息相关的有用属性也是clientHeight，scrollWidth，scrollHeight。

Answer 2

以下是如何知道滚动条是否可见的方法。为简洁而错过了一些错误检查。

LPDISPATCH      lpDispatch;
lpDispatch      = m_Browser.GetDocument();

IHTMLDocument2 *doc2 = NULL;
disp->QueryInterface(IID_IHTMLDocument2,(void**)&doc2);

IHTMLElement *lpBodyElement; 
IHTMLBodyElement *lpBody; 

doc2->get_body(&lpBodyElement); 
if ( lpBodyElement )
{
lpBodyElement->QueryInterface(IID_IHTMLBodyElement,(void**)&lpBody); 
if ( lpBody )
{
    BSTR bstrText; 
            pBody->get_scroll(&bstrText);
    lpBody->Release(); 
}
lpBodyElement->Release(); 
}
doc2->Release();

bstrText的可能值为“yes”，“no”，“auto”（当页面内容超出客户区时显示滚动条）

以下是您了解当前滚动位置的方法：

IHTMLElement2 *pElement = NULL;
hr = pBody->QueryInterface(IID_IHTMLElement2,(void**)&pElement);
ASSERT(SUCCEEDED(hr));
ASSERT( pElement );
long scroll_pos;
pElement->get_scrollTop( &scroll_pos);

如何获取有关Webbrowser控件实例或IE Webrowser的滚动条的信息？

2 个答案: