Question

我最近开始使用vim，但是我错过了其他文本编辑器中的字符/行选择方法。默认情况下，vim会映射<S-Up>，<S-Down>向上/向下跳转一页，我想将其重新映射到文本选择。

有办法吗？

Answer 1

我用插入模式的那些完成了@escrafford映射：

" shift+arrow selection
nmap <S-Up> v<Up>
nmap <S-Down> v<Down>
nmap <S-Left> v<Left>
nmap <S-Right> v<Right>
vmap <S-Up> <Up>
vmap <S-Down> <Down>
vmap <S-Left> <Left>
vmap <S-Right> <Right>
imap <S-Up> <Esc>v<Up>
imap <S-Down> <Esc>v<Down>
imap <S-Left> <Esc>v<Left>
imap <S-Right> <Esc>v<Right>

同样映射通常的复制/剪切/粘贴，例如，您可以在select + copy之后返回插入模式。

vmap <C-c> y<Esc>i
vmap <C-x> d<Esc>i
map <C-v> pi
imap <C-v> <Esc>pi
imap <C-z> <Esc>ui

现在您可以从任何模式开始移位+箭头选择，然后从C-c开始复制，然后从C-v开始粘贴。您总是以插入模式结束，因此您还可以使用C-z进行撤消。

我认为这更接近于yu要求的文本编辑器的“预期标准”行为。

Answer 2

与progo的答案略有不同 - 这给出了与mac应用程序通常相同的感觉：

nmap <S-Up> v<Up>
nmap <S-Down> v<Down>
nmap <S-Left> v<Left>
nmap <S-Right> v<Right>
vmap <S-Up> <Up>
vmap <S-Down> <Down>
vmap <S-Left> <Left>
vmap <S-Right> <Right>

差异是切换到视觉模式而不是视觉线模式，而不会丢失初始上/下等键击。

Answer 3

在我看来，Vim并没有那么容易弯腰。在我的情况下，终端机甚至不识别Shift-Up！我认为v（字符选择）或V（行选择）是了解vi / vim的更简单的概念。

如果这样做（现在无法测试），这就是你想要的东西：

" activate visual mode in normal mode
nmap <S-Up> V
nmap <S-Down> V
" these are mapped in visual mode
vmap <S-Up> k
vmap <S-Down> j
" 
" etc...
" similarly <S-Left>, <S-Right> for v

Answer 4

有一个特定的选项：keymodel：

'keymodel' 'km'     string  (default "")
            global
            {not in Vi}
    List of comma separated words, which enable special things that keys
    can do.  These values can be used:
       startsel Using a shifted special key starts selection (either
            Select mode or Visual mode, depending on "key" being
            present in 'selectmode').
       stopsel  Using a not-shifted special key stops selection.
    Special keys in this context are the cursor keys, <End>, <Home>,
    <PageUp> and <PageDown>.
    The 'keymodel' option is set by the |:behave| command.

TL; DR ：要启用所需的行为，请使用：

set keymodel=startsel

如果您还希望在使用<Up>或<Down>而未按<Shift>时离开可视模式，则可以使用：

set keymodel=startsel,stopsel

Answer 5

我找到了另一种更容易执行的解决方案。命令'：behave mswin'执行使用shift加光标键选择文本所需的全部操作。从任何模式工作。它还支持Cmd-c，Cmd-v和Cmd-x。它适用于MacVim，但我没有尝试其他平台。

Answer 6

绝对建议您不要重新映射此功能。只需切换到可视模式并使用v和箭头键是一个更好的主意。 V将选择整行，v$将选择行的末尾，vw将选择下一个单词。您可以使用更多命令来选择不同的行和单词。学习这些命令不仅对选择有用，而且对于更有效地编辑文件也很有用。

Answer 7

此映射在选择期间保持插入模式（可视模式），并且从正确的位置开始。您还可以使用Ctrl-Shift-左/右（如果您的终端支持），在左侧或右侧选择一个单词：

" Select with shift + arrows
inoremap    <S-Left>              <Left><C-o>v
inoremap    <S-Right>             <C-o>v
inoremap    <S-Up>                <Left><C-o>v<Up><Right>
inoremap    <S-Down>              <C-o>v<Down><Left>
imap        <C-S-Left>            <S-Left><C-Left>
imap        <C-S-Right>           <S-Right><C-Right>
vnoremap    <S-Left>              <Left>
vnoremap    <S-Right>             <Right>
vnoremap    <S-Up>                <Up>
vnoremap    <S-Down>              <Down>

" Auto unselect when not holding shift
vmap        <Left>                <Esc>
vmap        <Right>               <Esc><Right>
vmap        <Up>                  <Esc><Up>
vmap        <Down>                <Esc><Down>

这对于在插入模式下快速选择较小的零件很有用，但我建议使用默认命令选择较大的零件。

Answer 8

我已将此代码编写为能够在插入，可视和普通模式下使用Alt+hjkl（和朋友）进行导航并使用Alt+HJLK进行选择。

因此，同样的方法也可以应用于普通的箭头键

let hjklfriends = ['h','j','k','l','w','e','b','W','E','B', 'n', 'N', 'y', 'Y', 'p', 'P']

" define if using alt (it works in neovim) or Escape key.
function! Meta(key)
  if has('nvim')
        return "<A-" . a:key . ">"
    else
        return "<Esc>" . a:key
    endif
endfunction

execute 'noremap! ' . Meta('h') . ' <left>'
execute 'noremap! ' . Meta('j') . ' <down>'
execute 'noremap! ' . Meta('k') . ' <up>'
execute 'noremap! ' . Meta('l') . ' <right>'
execute 'noremap! ' . Meta('b') . ' <C-Left>'
execute 'noremap! ' . Meta('w') . ' <C-Right>'
execute 'noremap! ' . Meta('e') . ' <C-Right>'

for k in hjklfriends
  execute 'imap ' . Meta(k) . ' <C-o>' . k

  if k =~ '[a-z]'
    execute 'imap ' . Meta(toupper(k)) . ' <C-o>v' . k
    execute 'vmap ' . Meta(toupper(k)) . ' ' . k
    execute 'nmap ' . Meta(toupper(k)) . ' v' . k
  endif
endfor

映射<shift> - 按箭头选择字符/行</shift>

8 个答案: