Question

将方法作为参数传递不是问题：

type
  TSomething = class
    Msg: string;
    procedure Show;
  end;

procedure TSomething.Show;
begin
  ShowMessage(Msg);
end;

type TProc = procedure of object;

procedure Test(Proc: TProc);
begin
  Proc;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Smth: TSomething;

begin
  Smth:= TSomething.Create;
  Smth.Msg:= 'Hello';
  Test(Smth.Show);
end;

我需要一些棘手的东西 - 只传递一个方法的代码部分。我知道我能做到：

procedure Test2(Code: Pointer);
var
  Smth: TSomething;
  Meth: TMethod;

begin
  Smth:= TSomething.Create;
  Smth.Msg:= 'Hello Hack';
  Meth.Data:= Smth;
  Meth.Code:= Code;
  TProc(Meth);
  Smth.Free;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  Test2(@TSomething.Show);
end;

但这是一个黑客并且不安全 - 编译器无法检查方法的参数。

问题：是否有可能以类型安全的方式做同样的事情？

Answer 1

我终于明白了。使用类型检查，无需为调用事件声明变量！

type

  TSomething = class
    Msg: string;
    procedure Show;
    procedure ShowWithHeader(Header : String);
  end;

  TProc = procedure of object;
  TStringMethod = procedure(S : String) of Object;

procedure TSomething.Show;
begin
  ShowMessage(Msg);
end;

procedure TSomething.ShowWithHeader(Header: String);
begin
  ShowMessage(Header + ' : ' + Msg);
end;

procedure Test2(Code: TProc);
var
  Smth: TSomething;
begin
  Smth:= TSomething.Create;
  Smth.Msg:= 'Hello Hack 2';
  TMethod(Code).Data := Smth;
  Code;
  Smth.Free;
end;

procedure Test3(Code: TStringMethod; S : String);
var
  Smth: TSomething;
begin
  Smth:= TSomething.Create;
  Smth.Msg:= 'Hello Hack 3';
  TMethod(Code).Data := Smth;
  Code(S);
  Smth.Free;
end;

procedure TForm4.btn1Click(Sender: TObject);
begin
  Test2(TSomething(nil).Show);
//  Test2(TSomething(nil).ShowWithHeader); // Cannot Compile
end;

procedure TForm4.btn2Click(Sender: TObject);
begin
//  Test3(TSomething(nil).Show,'Hack Header');  // Cannot Compile
  Test3(TSomething(nil).ShowWithHeader,'Hack Header');
end;

Answer 2

我最终采用了基于存根函数的解决方法。它没有回答我原来的问题，包含一个存根开销，但用重复的代码解决了我的问题并且没有hackish代码：

type
  TSmth = class
    procedure Method1;
    procedure Method2;
  end;

type
  TDoMethod = procedure(Instance: TSmth);

procedure DoMethod1(Instance: TSmth);
begin
  Instance.Method1;
end;

procedure DoMethod2(Instance: TSmth);
begin
  Instance.Method2;
end;

procedure TestMethod(DoMethod: TDoMethod);
var
  Smth: TSmth;

begin
  Smth:= TSmth.Create;
{ a lot of common setup code here }
  DoMethod(Smth);
{ a lot of common check code here }
  Smth.Free;
end;

procedure TestMethod1;
begin
  TestMethod(DoMethod1);
end;

procedure TestMethod2;
begin
  TestMethod(DoMethod2);
end;

Answer 3

免责声明：我个人绝不会使用此代码，也绝不会推荐或宽恕其使用。

这样做：

procedure Test2(Method: TProc);
var
  Smth: TSomething;
begin
  Smth:= TSomething.Create;
  Smth.Msg:= 'Hello Hack';
  TMethod(Method).Data:= Smth;
  Method();
end;

当然，这仍然是不安全的，因为只有当您放入Data的内容实际上与该方法兼容时，它才会起作用。

Serg问：

如果不创建TSomething的虚拟实例，您将如何调用Test2？

我认为你可以这样做，对于静态（即非虚拟和非动态）方法：

var
  Obj: TSomething;
....
Test2(Obj.Show);//no need to actually create Obj

当然，这一切都说明了这是一个奇怪的黑客行为。我认为这并不比你问题中的版本好。没有真正干净的方式来做你所要求的。

我怀疑解决问题的正确方法是使用RTTI来调用方法。

Answer 4

这是使用匿名方法的示例。

没有代码重复和类型安全方法调用。

type
  TSmth = class
    procedure Method1;
    procedure Method2;
  end;

procedure Test;
type
  TMyMethodRef = reference to procedure;
  PMyTestRef = reference to procedure(aMethod :TMyMethodRef);
var
  TestP : PMyTestRef;
  Smth : TSmth;
begin
  TestP :=
    procedure( aMethod : TMyMethodRef)
    begin
      Smth := TSmth.Create;
      try
        // setup Smth
        aMethod;
        // test Smth 
      finally
        Smth.Free;
      end;
    end;

  TestP(Smth.Method1); // Test Method1
  TestP(Smth.Method2); // Test Method2    
end;

以类型安全的方式将方法的代码作为参数传递

4 个答案: