Question

是否有可能从一个进程连接到Oracle（通过OCI），然后从另一个进程连接到同一个数据库会话？

在我当前的应用程序中，有两种方法可以访问数据库：同步数据库和异步数据库（通过使用单独的进程，通过套接字进行通信）。问题是这两种方法实现了不同的会话。

如果我尝试例如一个会话的更新，然后尝试从另一个会话更新同一个表而不提交，我在OCI调用上挂起。

更糟糕的是，如果会话变量是从一个会话设置的 - 另一个会话没有看到它（这正是名称所说的......）。

Answer 1

如果您使用的是11g数据库，则可以使用DBMS_XA package允许一个会话加入第一个会话启动的事务。正如Tim Hall deomonstrates所述，您可以在一个会话中启动事务，从另一个会话加入该事务，并读取事务中所做的未提交的更改。但遗憾的是，这对会话变量没有帮助（假设“会话变量”表示具有会话范围的包变量）。

创建包和表：

CREATE TABLE foo( col1 NUMBER );

create or replace package pkg_foo
as
  g_var number;
  procedure set_var( p_in number );
end;

create or replace package body pkg_foo
as
  procedure set_var( p_in number )
  as
  begin
    g_var := p_in;
  end;
end;

在第1节中，我们启动一个全局事务，设置包变量，并在挂起全局事务（允许另一个会话恢复它）之前在表中插入一行

SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4  begin
  5    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmnoflags );
  6    pkg_foo.set_var(42);
  7    dbms_output.put_line( 'Set pkg_foo.g_var to ' || pkg_foo.g_var );
  8    insert into foo values( 42 );
  9    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuspend );
 10* end;
SQL> /
Set pkg_foo.g_var to 42

PL/SQL procedure successfully completed.

在会话2中，我们恢复全局事务，从表中读取，读取会话变量，并结束全局事务。请注意，针对表的查询会看到我们插入的行，但包变量更改不可见。

SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4    l_col1 integer;
  5  begin
  6    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmresume );
  7    dbms_output.put_line( 'Read pkg_foo.g_var as ' || pkg_foo.g_var );
  8    select col1 into l_col1 from foo;
  9    dbms_output.put_line( 'Read COL1 from FOO as ' || l_col1 );
 10    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuccess );
 11* end;
SQL> /
Read pkg_foo.g_var as
Read COL1 from FOO as 42

PL/SQL procedure successfully completed.

要在会话之间共享会话状态，是否可以使用global application context而不是使用包变量？如果要同时读取数据库表和会话状态，可以将其与DBMS_XA包结合使用。

使用getter和setter

创建上下文和包

CREATE CONTEXT my_context
  USING pkg_foo
  ACCESSED GLOBALLY;

create or replace package pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number );
  function get_var( p_session_id in number )
    return number;
end;

create or replace package body pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number )
  as
  begin
    dbms_session.set_identifier( p_session_id );
    dbms_session.set_context( 'MY_CONTEXT', 'G_VAR', p_in, null, p_session_id );
  end;
  function get_var( p_session_id in number )
    return number
  is
  begin
    dbms_session.set_identifier( p_session_id );
    return sys_context('MY_CONTEXT', 'G_VAR');
  end;
end;

在会话1中，将会话12345的上下文变量G_VAR的值设置为47

begin
  pkg_foo.set_var( 12345, 47 );
end;

现在，会话2可以从上下文中读取值

  1* select pkg_foo.get_var( 12345 ) from dual
SQL> /

PKG_FOO.GET_VAR(12345)
----------------------
                    47

我可以从两个oci客户端维护一个Oracle会话吗？

1 个答案: