Question

opendir(DIR,"$pwd") or die "Cannot open $pwd\n";
    my @files = readdir(DIR);
    closedir(DIR);
    foreach my $file (@files) {
        next if ($file !~ /\.txt$/i);
        my $mtime = (stat($file))[9];
        print $mtime;
        print "\n";
    }

基本上我想要记下目录中所有txt文件的时间戳。如果有子目录，我也希望在该子目录中包含文件。

有人可以帮我修改上面的代码，以便它也包含子目录。

如果我在windows中使用下面的代码iam获取文件夹中所有文件的时间戳，甚至在我的文件夹之外

 my @dirs = ("C:\\Users\\peter\\Desktop\\folder");
    my %seen;
    while (my $pwd = shift @dirs) {
            opendir(DIR,"$pwd") or die "Cannot open $pwd\n";
            my @files = readdir(DIR);
            closedir(DIR);
            #print @files;
            foreach my $file (@files) {
                    if (-d $file and !$seen{$file}) {
                            $seen{$file} = 1;
                            push @dirs, "$pwd/$file";
                    }
                    next if ($file !~ /\.txt$/i);
                    my $mtime = (stat("$pwd\$file"))[9];
                    print "$pwd $file $mtime";
                    print "\n";
            }
    }

Answer 1

File::Find最适合这个。它是一个核心模块，因此不需要安装。此代码与您似乎想到的相同

use strict;
use warnings;

use File::Find;

find(sub {
  if (-f and /\.txt$/) {
    my $mtime = (stat _)[9];
    print "$mtime\n";
  }
}, '.');

其中'.'是要扫描的目录树的根目录;如果您愿意，可以在这里使用$pwd。在子例程中，Perl对找到文件的目录执行了chdir，将$_设置为文件名，并将$File::Find::name设置为包含路径的完全限定文件名

Answer 2

use warnings;
use strict;

my @dirs = (".");
my %seen;
while (my $pwd = shift @dirs) {
        opendir(DIR,"$pwd") or die "Cannot open $pwd\n";
        my @files = readdir(DIR);
        closedir(DIR);
        foreach my $file (@files) {
                next if $file =~ /^\.\.?$/;
                my $path = "$pwd/$file";
                if (-d $path) {
                        next if $seen{$path};
                        $seen{$path} = 1;
                        push @dirs, $path;
                }
                next if ($path !~ /\.txt$/i);
                my $mtime = (stat($path))[9];
                print "$path $mtime\n";
        }
}

Answer 3

使用File::Find::Rule

File :: Find :: Rule是File :: Find的友好界面。它允许您构建指定所需文件和目录的规则。

Answer 4

您可以使用递归：定义一个遍历文件并在目录上调用自身的函数。然后调用顶层目录中的函数。

另见File::Find。

Answer 5

如果我在windows中使用下面的代码iam获取文件夹中所有文件的时间戳，甚至在我的文件夹之外

我怀疑这个问题可能是.和..目录的一个问题，如果您尝试按照这些目录操作，则会将向上目录树。你错过的是：

foreach my $file (@files) {
    # skip . and .. which cause recursion and moving up the tree
    next if $file =~ /^\.\.?$/;
    ...

您的脚本也会遇到一些错误。 $file与$dir无关，因此-d $file只能在当前目录中使用，而不是在下面。

这是我的固定版本：

use warnings;
use strict;

# if unix, change to "/";
my $FILE_PATH_SLASH = "\\";    
my @dirs = (".");
my %seen;
while (my $dir = shift @dirs) {
        opendir(DIR, $dir) or die "Cannot open $dir\n";
        my @files = readdir(DIR);
        closedir(DIR);
        foreach my $file (@files) {
                # skip . and ..
                next if $file =~ /^\.\.?$/;
                my $path = "$dir$FILE_PATH_SLASH$file";
                if (-d $path) {
                        next if $seen{$path};
                        $seen{$path} = 1;
                        push @dirs, $path;
                }
                next unless $path ~= /\.txt$/i;
                my $mtime = (stat($path))[9];
                print "$path $mtime\n";
        }
}

如何遍历目录中的所有文件;如果它有子目录，我也想遍历子目录中的文件

5 个答案: