Question

我正在尝试使用ANTLR 3.4构建C--编译器。

此处列出的完整语法集

program         : (vardeclaration | fundeclaration)*                    ;
vardeclaration  : INT ID (OPENSQ NUM CLOSESQ)? SEMICOL  ;

fundeclaration  : typespecifier ID OPENP params CLOSEP compoundstmt     ;
typespecifier   : INT | VOID                                            ;
params          : VOID | paramlist                                      ;
paramlist       : param (COMMA param)*                                  ;
param           :  INT ID (OPENSQ CLOSESQ)?         ;

compoundstmt    : OPENCUR vardeclaration* statement* CLOSECUR           ;
statementlist   : statement*                                            ;

statement       : expressionstmt | compoundstmt | selectionstmt | iterationstmt | returnstmt;
expressionstmt  : (expression)? SEMICOL;
selectionstmt   : IF OPENP expression CLOSEP statement (options {greedy=true;}: ELSE statement)?;
iterationstmt   : WHILE OPENP expression CLOSEP statement;
returnstmt      : RETURN (expression)? SEMICOL;

expression      : (var EQUAL expression) | sampleexpression;
var             : ID ( OPENSQ expression CLOSESQ )? ;

sampleexpression: addexpr ( ( LOREQ | LESS | GRTR | GOREQ | EQUAL | NTEQL) addexpr)?;
addexpr         : mulexpr ( ( PLUS | MINUS ) mulexpr)*;
mulexpr         : factor  ( ( MULTI | DIV  ) factor )*; 

factor          : ( OPENP expression CLOSEP ) | var | call  | NUM;
call            : ID OPENP arglist? CLOSEP;
arglist         : expression ( COMMA expression)*;

使用的词法规则如下，

ELSE    : 'else'    ;
IF      : 'if'      ;
INT     : 'int'     ;
RETURN  : 'return'  ;
VOID    : 'void'    ;
WHILE   : 'while'   ;

PLUS    : '+' ;
MINUS   : '-' ;
MULTI   : '*' ;
DIV     : '/' ;

LESS    : '<'  ;
LOREQ   : '<=' ;
GRTR    : '>'  ;
GOREQ   : '>=' ;

EQUAL   : '==' ;
NTEQL   : '!=' ;
ASSIGN  : '='  ;

SEMICOL : ';' ;
COMMA   : ',' ;

OPENP   : '(' ;
CLOSEP  : ')' ;
OPENSQ  : '[' ;
CLOSESQ : ']' ;
OPENCUR : '{' ;
CLOSECUR: '}' ;

SCOMMENT: '/*' ;
ECOMMENT: '*/' ;


ID  : ('a'..'z' | 'A'..'Z')+/*(' ')*/ ;
NUM : ('0'..'9')+ ;
WS  : (' ' | '\t' | '\n' | '\r')+ {$channel = HIDDEN;};
COMMENT: '/*' .* '*/' {$channel = HIDDEN;};

但是我试图保存它，它给我错误，

error(211): /CMinusMinus/src/CMinusMinus/CMinusMinus.g:33:13: [fatal] rule expression has non-LL(*) decision due to recursive rule invocations reachable from alts 1,2.  Resolve by left-factoring or using syntactic predicates or using backtrack=true option.
 |---> expression       : (var EQUAL expression) | sampleexpression;

1 error

如何解决此问题？

Answer 1

如上所述：您的语法规则expression含糊不清：该规则中的两个备选方案都可以开始，或者可以是var。

你需要“帮助”你的解析器。如果解析可以看到var后跟EQUAL，则应选择备选1，否则备选2.这可以通过使用句法谓词（规则中的(var EQUAL)=>部分来完成下文）。

expression
 : (var EQUAL)=> var EQUAL expression
 |               sampleexpression
 ;

有关此问答中的谓词的更多信息：What is a 'semantic predicate' in ANTLR?

Answer 2

问题在于：

expression      : (var EQUAL expression) | sampleexpression;

您可以从var或sampleexpression开始。但sampleexpression也可以通过var

将sampleexpression->addExpr->MultExpr->Factor->var缩减为backtrack=true

因此无法为编译器找到k长度谓词。

您可以按照错误消息集{{1}}的建议来查看这是否可以解决您的问题，但是它可能不会导致AST - 您期望的parsetrees，并且在特殊输入条件下也可能会很慢。您也可以尝试重构语法以避免这种递归。

ANTLR语法错误

2 个答案: