Question

我正在使用Groovy 1.8.4，试图获取封闭函数的名称......

def myFunction() {
  println functionName??
}

我已尝试delegate，this，owner，Groovy抱怨没有找到此类对象。

我也尝试过Java hack new Exception().getStackTrace()[0].getMethodName()，但只打印newInstance0

Answer 1

groovy的StackTraceUtils.sanitize怎么样？这是一个简单的例子：

import org.codehaus.groovy.runtime.StackTraceUtils

class A {
  def methodX() {
    methodY()
  }

  def methodY() {
    methodZ()
  }

  def methodZ() {
    def marker = new Throwable()
    StackTraceUtils.sanitize(marker).stackTrace.eachWithIndex { e, i ->
        println "> $i ${e.toString().padRight(30)} ${e.methodName}"
    }
  }

}

new A().methodX()

粘贴到独立脚本test.groovy时的上述输出如下：

$ groovy test.groovy 
> 0 A.methodZ(test.groovy:13)      methodZ
> 1 A.methodY(test.groovy:9)       methodY
> 2 A.methodX(test.groovy:5)       methodX
> 3 A$methodX.call(Unknown Source) call
> 4 test.run(test.groovy:21)       run

sanitize方法从跟踪过滤掉所有groovy内部mumbo jumbo，清晰的跟踪与...stackTrace.find { }一起应该给你一个不错的开始。

Answer 2

import org.codehaus.groovy.runtime.StackTraceUtils

def getCurrentMethodName(){
  def marker = new Throwable()
  return StackTraceUtils.sanitize(marker).stackTrace[1].methodName
}

def helloFun(){
   println( getCurrentMethodName() )
}

helloFun()

输出：

helloFun

Answer 3

你可以通过堆栈跟踪获得它，我已经能够通过：

获得它

groovy:000> def foo() { println Thread.currentThread().stackTrace[10].methodName }
===> true
groovy:000> foo()
foo
groovy:000> class Foo {                                                             
groovy:001>   def bar() { println Thread.currentThread().stackTrace[10].methodName }
groovy:002> }
===> true
groovy:000> new Foo().bar()
bar

Answer 4

@CompileStatic
class LogUtils {
    // can be called the Groovy or Java way
    public static String getCurrentMethodName(){
        StackTraceElement[] stackTrace = StackTraceUtils.sanitize(new Throwable()).stackTrace
        stackTrace[2].methodName != 'jlrMethodInvoke' ? stackTrace[2].methodName : stackTrace[3].methodName
    }
}

Groovy，附上函数的名字？

4 个答案: