Question

仍在学习Groovy的绳索，这个问题从昨晚开始惹恼了我。不确定为什么它会抛出concurrentmod异常......（Java 1.6，Groovy 1.8.4）

我有一个按键列表...... [1,2,3,4,5,6,7,8,9,10,11,12,13]

我使用自here得到的自定义函数partitionList(keys,3)整理列表（不能使用java.List.Collate，不能使用1.8.6）

现在我有一份清单...... [[0,1,2],[3,4,5],[6,7,8],[9,10,11],[12,13]]

如果创建的子列表数量是奇数，我删除最后一个子列表[12,13]并在其他子列表中按顺序重新分配其键，创建...

[[0,1,2,12],[3,4,5,13],[6,7,8],[9,10,11]]

迭代最后一个子列表的值时发生异常。不知道为什么，因为我正在迭代列表并在该循环中更改完全不同的列表...

更新

有趣......如果我不使用paritionList()功能，则替换 def keyRanges = partitionList( keys, 3) 明确的清单列表...... def keyRanges = [[0,1,2],[3,4,5],[6,7,8],[9,10,11],[12,13]] 问题消失了。所以我认为partitionList（）函数正在做一些导致异常的事情

class CollateListTest {

    static main(args) {    
        def keys = (0..13).toList()

        //partition the keys into a list of lists 
        def keyRanges = partitionList( keys, 3)
        println 'Key range sets...'
        for( keyRange in keyRanges)
            println keyRange

        //if odd number of partitions, 
        //remove last sub list and redistribute values over other lists
        if( (keyRanges.size() % 2) != 0){
            def lastKeyRange = keyRanges.remove( keyRanges.size() - 1 )
            println 'removed range: ' + lastKeyRange

                    // ** EXCEPTION HERE **         
            lastKeyRange.eachWithIndex{ k, index ->
                println 'adding: ' + k
                keyRanges[ index % keyRanges.size()].add( k)
            }
        }
    }

    //from stackoverflow.com/questions/2924395/
    static def partitionList(list, size) {
        def partitions = []
        int partitionCount = list.size() / size

        partitionCount.times { partitionNumber ->
            def start = partitionNumber * size
            def end = start + size - 1
            partitions << list[start..end]
        }

        if (list.size() % size) partitions << list[partitionCount * size..-1]
        return partitions
    }
}

Answer 1

您使用的partitionList方法会将列表与List.getAt(Range)分开。这会将视图返回到原始列表中，但不会复制数据，因此对子列表的任何修改也会影响原始列表。

这意味着lastKeyRange与keyRanges共享数据，并且添加到其中一个子列表会间接影响您正在迭代的子列表。而不是修改子列表，只需创建一个新的子列表。例如：

if( (keyRanges.size() % 2) != 0){
    def lastKeyRange = keyRanges.remove( keyRanges.size() - 1 )
    println 'removed range: ' + lastKeyRange

    lastKeyRange.eachWithIndex{ k, index ->
        println 'adding: ' + k
        def newRange = []
        newRange.addAll(keyRanges[ index % keyRanges.size()])
        newRange.add(k)
        keyRanges[ index % keyRanges.size()] = newRange

    }
}

Groovy，整理列表导致并发修改异常

1 个答案: