Question

我有一个这样的文件：

n A B C D 
1 01 02 01 01
2 02 02 01 01

我希望按行传输列，因此输出应该是这样的：

我写了这个命令：

awk '{ for (i=1;i<=NF;i++ ) printf $i " " }' file.txt > out-file.txt

问题是这个命令把所有东西放在一行！所以输出是这样的：

n 1 2 A 01 02 B 02 02 C 01 01 D 01 01

Answer 1

这可能有效：

awk '{
       for (f = 1; f <= NF; f++) { a[NR, f] = $f } 
     }
     NF > nf { nf = NF }
     END {
       for (f = 1; f <= nf; f++) {
           for (r = 1; r <= NR; r++) {
               printf a[r, f] (r==NR ? RS : FS)
           }
       }
    }' YOURINPUT

见in action @ Ideone。

Answer 2

将此脚本另存为transpose.awk和chmod u+x transpose.awk。这是Tim Sherwood's transpose的修改。

#!/usr/bin/gawk -f

BEGIN {
    max_x =0;
    max_y =0;
}

{
    max_y++;
    for( i=1; i<=NF; i++ )
    {
        if (i>max_x) max_x=i;
        A[i,max_y] = $i;
    }
}

END {
    for ( x=1; x<=max_x; x++ )
    {
        for ( y=1; y<=max_y; y++ )
        {
            if ( (x,y) in A ) printf "%s",A[x,y];
            if ( y!=max_y ) printf " ";
        }
        printf "\n";
    }
}

示例：

$ ./transpose.awk example
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

Answer 3

使用rs：

会更容易

$ cat /tmp/a
n A B C D
1 01 02 01 01
2 02 02 01 01
$ rs -c' ' -C' ' -T</tmp/a
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

-c更改输入列分隔符，-C更改输出列分隔符，-T转置行和列。

Answer 4

好吧，没有awk，我们可以使用cat执行此操作：

for x in `cat filename`
do
echo $x
done

使用此脚本，结果将出现在cols中。

Answer 5

这是一个不同的解决方案，最后只涉及一个for循环：

{ for (i=1; i<=NF; i++) col[i] = col[i] " " $i }
END { 
    for (i=1; i<=NF; i++) { 
        sub(/^ /, "", col[i]); 
        print col[i] 
    } 
}

讨论

此解决方案使用单维数组 col ，它存储整列的值。 col [1] 是第一列。
对于每一行，我们将列附加到col [i]。因为我们盲目追加， col [i] 值将包含一个前导空格。
最后，sub（）函数在打印出列（现在是一行）之前删除前导空格

如何将列数据传输到行（使用awk）？

5 个答案:

讨论