Question

我正在使用Spreadsheet::ParseExcel模块。我想用Excel数据创建哈希哈希：

{
    'P343453' => {
        'Date'   => 03022011,
        'Method' => 'No',
        'Time'   => 1440,
    },
    'P343763' => {
        'Date'   => 03022011,
        'Method' => 'YES',
        'Time'   => '1745',
    }
}

我现在拥有的是这样的：

{
    'P343453' => [
        '03022011',
        'No',
        '1440',
    ],
    'P343763' => [
        '03022011',
        'YES',
        '1745',
    ],
}

这是我的代码：

my @worksheets = $workbook->worksheets();
warn "More than 1 worksheet found\n" if @worksheets > 1;

# Only work with first page.
my $worksheet = $worksheets[0];

my ( $row_min, $row_max ) = $worksheet->row_range();
my ( $col_min, $col_max ) = $worksheet->col_range();
my @required_col = (1 .. $col_max);
my @value;

##to get the headers of the excel file;
for my $row ( 0 .. 0 ) {
    @value = map {
        my $cell = $worksheet->get_cell($row, $_);
        $cell ? $cell->value() : '';
    } @required_col;
}

# Skip header row
my $sample_details = {};
for my $row (1  .. $row_max ) {
    my @data = map {
        my $cell = $worksheet->get_cell($row, $_);
        $cell ? $cell->value() : '';
    } @required_col;
    $sample_details->{$worksheet->get_cell($row,0)->value()} = \@data
        if defined $worksheet->get_cell($row, 0)->value();
}

我应该如何修改代码以将键分配给数组@value中哈希的hashref？

Answer 1

# Skip header row
my $sample_details = {};
for my $row (1  .. $row_max ) {
  my  @data = map {
        my $cell = $worksheet->get_cell($row, $_);
        $cell ? $cell->value() : '';
    } @required_col;

  foreach my $col (@values) {
    $sample_details->{$worksheet->get_cell($row,0)->value()}{$col} = shift @data  if defined $worksheet->get_cell($row, 0)->value();
  }
}

Answer 2

将最后一行中的\@data替换为：

  { map { ($value[$_] => $data[$_]) } (0..$#value) }

这将使用相应的标题作为键从每个列表值创建一个键/值对。

如何从Spreadsheet :: ParseExcel数据创建哈希哈希？

2 个答案: