XSL基础知识：显示布尔值？

Question

当我在xsl中有这个时：

<xsl:choose>
  <xsl:when test="something > 0">
    <xsl:variable name="myVar" select="true()"/>
  </xsl:when>
  <xsl:otherwise>
    <xsl:variable name="myVar" select="false()"/>
  </xsl:otherwise>
</xsl:choose>

我怎样才能打印出＃34; myVar＆＃34;的价值？或者更重要的是，如何在另一个select语句中使用此布尔值？

Answer 1

<xsl:choose>
  <xsl:when test="something > 0">
    <xsl:variable name="myVar" select="true()"/>
  </xsl:when>
  <xsl:otherwise>
    <xsl:variable name="myVar" select="false()"/>
  </xsl:otherwise>
</xsl:choose>

这是非常错误和无用的，因为变量$myVar会立即超出范围。

有条件地分配给变量的一种正确方法是：

<xsl:variable name="myVar">
  <xsl:choose>
    <xsl:when test="something > 0">1</xsl:when>
    <xsl:otherwise>0</xsl:otherwise>
  </xsl:choose>
</xsl:variable>

但是，你真的不需要这个 - 更简单的是：

<xsl:variable name="myVar" select="something > 0"/>

How can I then print out the value of "myVar"?

使用：

<xsl:value-of select="$myVar"/>

  

或者更重要的是，如何在另一个选择中使用此布尔值   声明？

以下是一个简单示例：

<xsl:choose>
  <xsl:when test="$myVar">
   <!-- Do something -->
  </xsl:when>
  <xsl:otherwise>
   <!-- Do something else -->
  </xsl:otherwise>
</xsl:choose>

这是一个完整的例子：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*/*">
  <xsl:variable name="vNonNegative" select=". >= 0"/>

  <xsl:value-of select="name()"/>: <xsl:text/>

  <xsl:choose>
   <xsl:when test="$vNonNegative">Above zero</xsl:when>
   <xsl:otherwise>Below zero</xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于以下XML文档：

<temps>
 <Monday>-2</Monday>
 <Tuesday>3</Tuesday>
</temps>

产生了想要的正确结果：

 Monday: Below zero
 Tuesday: Above zero