Question

我正在检索控件的几个属性。以下是我用于检索属性的方法（使用PropertyInfo类型的pinfo）：

value = pinfo.GetValue(obj, nothing)

这很好用，但现在我面对的是一个具有可选值的属性，我收到一条错误消息，告诉我参数的数量不正确。所以我改变了我的代码：

Dim index As Object() = {Nothing}
value = pinfo.GetValue(obj, index)

此时，我没有收到任何错误消息，但此代码未检索到正确的值。只有当我用属性访问器提供的默认值替换 Nothing 时它才有效...

但我事先并不知道这个默认值是多少！并且此代码在函数中检索没有可选值的属性，因此我无法更改代码，尤其是对于一种情况或其他情况。

有什么想法吗？我正在研究.NET 2.0

编辑：关于导致问题的案例的更精确

以下是导致问题的属性示例：

ReadOnly Property Foo(Optional ByVal Number As Integer = -1) As String
    Get
        If Number = -1 Then
            Return "Your number is the default number: " & Number
        Else
            Return "Your number is " & Number
        End If
    End Get
End Property

使用这种属性，上面的代码都没有检索到好的字符串。

我最好的猜测是尝试第一个代码用于一般用途，捕获相应的异常，然后动态检索参数的默认值（在这种情况下为数字）和输入，以便我可以使用此默认值调用getValue。

那么，如何检索可选参数的默认值？

Answer 1

这适用于可选参数：

ReadOnly Property Foo(Optional name As String = Nothing) As String
    Get
        If name Is Nothing Then
            Return "Hello World"
        Else
            Return "Hello " & name
        End If
    End Get
End Property


Dim pinfo As Reflection.PropertyInfo = Me.GetType().GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {"Tim"})  ' Hello Tim '
value = pinfo.GetValue(Me, New Object(){Nothing})               ' Hello World '

编辑：根据您的评论，整数不起作用，我还不知道如何在属性中获取可选参数的默认值。如果您知道它，您可以轻松传递它，但否则会发生以下情况（注意Int32.MinValue为默认值而不是0）：

ReadOnly Property Foo(Optional age As Int32 = Int32.MinValue) As String
    Get
        If age = Int32.MinValue Then
            Return "I don't know how old i am"
        Else
            Return String.Format("I am {0} years old", age)
        End If
    End Get
End Property

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {38})  ' I am 38 years old '
value = pinfo.GetValue(Me, New Object() {Nothing})           ' I am 0 years old '
value = pinfo.GetValue(Me, New Object() {Int32.MinValue})    ' I don't know how old i am '

Edit2 ：感谢@Rup现在我知道GetIndexParameters是缺失的部分。因此，以下内容适用于任何类型的参数。

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim parameters() As Reflection.ParameterInfo = pinfo.GetIndexParameters()
Dim params(parameters.Length - 1) As Object
For i As Int32 = 0 To parameters.Length - 1
    Dim paramInfo As Reflection.ParameterInfo = parameters(i)
    If paramInfo.IsOptional Then
        params(i) = paramInfo.DefaultValue
    Else
        If paramInfo.ParameterType.IsValueType Then
            params(i) = Activator.CreateInstance(paramInfo.ParameterType)
        Else
            params(i) = Nothing
        End If
    End If
Next
Dim value As Object = pinfo.GetValue(Me, params)

Answer 2

尝试以下示例。验证对象是否为null，然后使用Activator激活它。以下程序在C＃中。

class Program
{
    static void Main(string[] args)
    {
        Test testObj = null;
        testObj = testObj ?? Activator.CreateInstance<Test>();
        var ty = testObj.GetType().GetProperty("MyProperty").GetValue(testObj, null);

    }
}
public class Test
{
    public Test2 MyProperty { get; set; }
}
public class Test2
{
    public int Prty { get; set; }
}

通过反射获取其getter具有可选值的属性的值

2 个答案: