Question

我正在创建一个创建XML的应用程序，如下所示：

<?xml version="1.0" encoding="ISO-8859-1"?>
<?xml-stylesheet type="text/xsl" href="MyCDCatalog.xsl"?>
<catalog>
    <cd>
        <title>Empire Burlesque</title>
        <artist>Bob Dylan</artist>
        <price>10.90</price>
        <year>1985</year>
    </cd>
    <cd>
        <title>Hide your heart</title>
        <artist>Bonnie Tyler</artist>
        <price>9.90</price>
        <year>1988</year>
    </cd>
    <cd>
        <title>Greatest Hits</title>
        <artist>Dolly Parton</artist>
        <price>9.90</price>
        <year>1982</year>
    </cd>
    <cd>
        <title>One night only</title>
        <artist>Bee Gees</artist>
        <price>10.90</price>
        <year>1998</year>
    </cd>
    <cd>
        <title>Sylvias Mother</title>
        <artist>Dr.Hook</artist>
        <price>8.10</price>
        <year>1973</year>
    </cd>
    <cd>
        <title>Maggie May</title>
        <artist>Rod Stewart</artist>
        <price>8.50</price>
        <year>1990</year>
    </cd>
</catalog>

我还有一个名为MyCDCatalog.xsl（下面）的XSL文件，用于转换上面的XML文件。

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
  <html>
  <body>
    <h2>My CD Collection</h2>
    <table border="1">
      <xsl:for-each select="catalog/cd">
      <tr>
        <td><xsl:value-of select="artist" />'s <xsl:value-of select="title" /> (<xsl:value-of select="year" />):   $<xsl:value-of select="price" /></td>
      </tr>
      </xsl:for-each>
    </table>
  </body>
  </html>
</xsl:template>
</xsl:stylesheet>

目前，XSL文件返回单个列中的所有条目。如何在3列或更多列中获取输出？

我想要输出如下：

[cd1] [cd2] [cd3]
[cd4] [cd5] [cd6]....

其中

cd1 = Bob Dylan's Empire Burlesque (1985): $10.90
cd2 = Bonnie Tyler's Hide your heart (1988): $9.90
etc.

感谢您的帮助。

Answer 1

另一种方法是匹配第一，第四，第七（等）位置的 cd 。

<xsl:apply-templates select="cd[(position() - 1) mod $columns = 0]" mode="first"/>

$ columns 是包含列数的参数

然后，您可以通过查看以下兄弟姐妹的相关数量来匹配行中的 cd 元素：

<xsl:apply-templates select=".|following-sibling::cd[position() &lt; $columns]"/>

这是完整的XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html" indent="yes" omit-xml-declaration="yes" />
   <xsl:param name="columns" select="3"/>

   <xsl:template match="/catalog">
      <html>
         <body>
            <h2>My CD Collection</h2> 
            <table>
               <xsl:apply-templates select="cd[(position() - 1) mod $columns = 0]" mode="first"/>
            </table>
         </body>
      </html>
   </xsl:template>

   <xsl:template match="cd" mode="first">
      <tr>
         <xsl:apply-templates select=".|following-sibling::cd[position() &lt; $columns]"/>
         <xsl:if test="count(following-sibling::cd) &lt; ($columns - 1)">
            <xsl:call-template name="emptycell">
               <xsl:with-param name="cells" select="$columns - 1 - count(following-sibling::cd)"/>
            </xsl:call-template>
         </xsl:if>
      </tr>
   </xsl:template>

   <xsl:template match="cd">
      <td>
         <xsl:value-of select="concat(title, &apos; &apos;, artist)"/>
      </td>
   </xsl:template>

   <xsl:template name="emptycell">
      <xsl:param name="cells"/>
      <td/>
      <xsl:if test="$cells &gt; 1">
         <xsl:call-template name="emptycell">
            <xsl:with-param name="cells" select="$cells - 1"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

当应用于您的示例XML时，输出以下内容：

<html>
   <body>
      <h2>My CD Collection</h2>
      <table>
         <tr>
            <td>Empire Burlesque Bob Dylan</td>
            <td>Hide your heart Bonnie Tyler</td>
            <td>Greatest Hits Dolly Parton</td>
         </tr>
         <tr>
            <td>One night only Bee Gees</td>
            <td>Sylvias Mother Dr.Hook</td>
            <td>Maggie May Rod Stewart</td>
         </tr>
      </table>
   </body>
</html>

（我这里只输出名称和艺术家，但我相信您可以看到如何更改它以显示更多信息）

请注意，如果剩余的 cd 元素的数量少于行中的列数，则输出空单元格会有一些令人讨厌的递归模板。

例如，将参数更改为4，然后输出以下内容：

<table>
  <tr>
    <td>Empire Burlesque Bob Dylan</td>
    <td>Hide your heart Bonnie Tyler</td>
    <td>Greatest Hits Dolly Parton</td>
    <td>One night only Bee Gees</td>
  </tr>
  <tr>
    <td>Sylvias Mother Dr.Hook</td>
    <td>Maggie May Rod Stewart</td>
    <td />
    <td />
  </tr>
</table>

Answer 2

在XSLT 1.0中，使用以下命令：

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" indent="yes"/>
    <xsl:key name="grp" use="floor(count(preceding-sibling::cd) div 3)" match="catalog/cd"/>
    <xsl:template match="/">
        <html>
            <body>
                <h2>My CD Collection</h2>
                <table border="1">
                    <xsl:apply-templates
                        select="catalog/cd[generate-id() =
                            generate-id(key('grp',floor((position() - 1) div 3))[1])]"
                        mode="group"/>
                    <!-- note: index [1] is superfluous, because generate-id applied on node-set returns the id of the first element in the set -->
                </table>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="catalog/cd" mode="group">
      <xsl:variable
          name="groupitems"
          select="key('grp', floor(count(preceding-sibling::cd) div 3))"/>
        <tr>
            <xsl:for-each select="$groupitems">
                <td>
                    <xsl:value-of select="artist" />'s <xsl:value-of select="title" /> (<xsl:value-of select="year" />): $<xsl:value-of select="price" />
                </td>
            </xsl:for-each>
        </tr>
    </xsl:template>
</xsl:stylesheet>

说明：Muenchian分组。构造密钥让我有点头疼，因为起初我试图为use属性分配一个与position（）相关的值 - 但这不能正常工作。我在这个网站上发现了另一个线程，解释了要使用的内容：key and position() problem。

输出是所需的输出：

<html>
    <body>
        <h2>My CD Collection</h2>
        <table border="1">
            <tr>
                <td>Bob Dylan's Empire Burlesque (1985): $10.90</td>
                <td>Bonnie Tyler's Hide your heart (1988): $9.90</td>
                <td>Dolly Parton's Greatest Hits (1982): $9.90</td>
            </tr>
            <tr>
                <td>Bee Gees's One night only (1998): $10.90</td>
                <td>Dr.Hook's Sylvias Mother (1973): $8.10</td>
                <td>Rod Stewart's Maggie May (1990): $8.50</td>
            </tr>
        </table>
    </body>
</html>

Answer 3

EDIT3：

两个模板table_format和table_format2将完成这项工作。在全局变量中设置计数：

  <xsl:variable name="col_count" select="'3'"/>

col_count决定列数：）

还记得我用过

    <xsl:for-each select="catalog/cd[1]">

在第一个模板中..

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:variable name="col_count" select="'3'"/>

  <xsl:template match="/">
    <html>
      <body>
        <h2>My CD Collection</h2>
        <table border="1">
        <xsl:for-each select="catalog/cd[1]">
          <xsl:call-template name="table_format"/>
        </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>

  <xsl:template name="table_format">
    <xsl:param name="count" select="'1'"/>
      <tr>
        <xsl:call-template name="table_format2"/>
      </tr>
      <xsl:for-each select="../cd[$col_count + $count]">
        <xsl:call-template name="table_format">
          <xsl:with-param name="count" select="$count + $col_count"/>
        </xsl:call-template>
      </xsl:for-each>
  </xsl:template>

  <xsl:template name="table_format2">
    <xsl:param name="col_count2" select="1"/>
    <xsl:if test="$col_count2 &lt;= $col_count">
      <td>
        <xsl:value-of select="artist" />'s <xsl:value-of select="title" /> (<xsl:value-of select="year" />): $<xsl:value-of select="price" />
      </td>
      <xsl:for-each select="following-sibling::cd[1]">
        <xsl:call-template name="table_format2">
          <xsl:with-param name="col_count2" select="$col_count2 + 1"/>
        </xsl:call-template>
      </xsl:for-each>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

如何让XSL以多列显示结果？

3 个答案: