Question

我想创建一个TCP服务器并向客户端发送/接收消息，而不是TCP服务器的OnExecute事件。

发送/接收消息不是问题;我喜欢这样：

procedure TFormMain.SendMessage(IP, Msg: string);
var
  I: Integer;
begin
  with TCPServer.Contexts.LockList do
  try
    for I := 0 to Count-1 do
      if TIdContext(Items[I]).Connection.Socket.Binding.PeerIP = IP then
      begin
        TIdContext(Items[I]).Connection.IOHandler.WriteBuffer(Msg[1], Length(Msg));
        //  and/or Read 
        Break;
      end;
  finally
    TCPServer.Contexts.UnlockList;
  end;
end;

注1：如果我不使用OnExecute，程序会在客户端连接时引发异常注意2：如果我在不做任何事情的情况下使用OnExecute，则CPU使用率将达到％100 注3：我没有机会更改TCP客户端。

那我该怎么办？

Answer 1

TIdTCPServer默认情况下需要分配OnExecute个事件处理程序。要解决这个问题，您必须从TIdTCPServer派生一个新类并覆盖其虚拟CheckOkToBeActive()方法，并且还应覆盖虚拟DoExecute()以调用Sleep()。否则，只需指定一个事件处理程序并让它调用Sleep()。

但这不是TIdTCPServer的有效用法。更好的设计是不要直接从SendMessage()方法内部将出站数据写入客户端。这不仅容易出错（您不会从WriteBuffer()捕获异常）并在写入期间阻塞SendMessage()，而且它还会序列化您的通信（客户端2在客户端1首先执行之前无法接收数据）。更有效的设计是为每个客户端提供自己的线程安全出站队列，然后让SendMessage()根据需要将数据放入每个客户端的队列中。然后，您可以使用OnExecute事件检查每个客户端的队列并进行实际写入。这样，SendMessage()不再被阻止，不易出错，并且可以并行编写客户端（就像它们应该的那样）。

尝试这样的事情：

uses
  ..., IdThreadSafe;

type
  TMyContext = class(TIdServerContext)
  private
    FQueue: TIdThreadSafeStringList;
    FEvent: TEvent;
  public
    constructor Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil); override;
    destructor Destroy; override;
    procedure AddMsgToQueue(const Msg: String);
    function GetQueuedMsgs: TStrings;
  end;

constructor TMyContext.Create(AConnection: TIdTCPConnection; AYarn: TIdYarn; AList: TThreadList = nil);
begin
  inherited;
  FQueue := TIdThreadSafeStringList.Create;
  FEvent := TEvent.Create(nil, True, False, '');
end;

destructor TMyContext.Destroy;
begin
  FQueue.Free;
  FEvent.Free;
  inherited;
end;

procedure TMyContext.AddMsgToQueue(const Msg: String);
begin
  with FQueue.Lock do
  try
    Add(Msg);
    FEvent.SetEvent;
  finally
    FQueue.Unlock;
  end;
end;

function TMyContext.GetQueuedMsgs: TStrings;
var
  List: TStringList;
begin
  Result := nil;
  if FEvent.WaitFor(1000) <> wrSignaled then Exit;
  List := FQueue.Lock;
  try
    if List.Count > 0 then
    begin
      Result := TStringList.Create;
      try
        Result.Assign(List);
        List.Clear;
      except
        Result.Free;
        raise;
      end;
    end;
    FEvent.ResetEvent;
  finally
    FQueue.Unlock;
  end;
end;

procedure TFormMain.FormCreate(Sender: TObject);
begin
  TCPServer.ContextClass := TMyContext;
end; 

procedure TFormMain.TCPServerExecute(AContext: TIdContext);
var
  List: TStrings;
  I: Integer;
begin
  List := TMyContext(AContext).GetQueuedMsgs;
  if List = nil then Exit;
  try
    for I := 0 to List.Count-1 do
      AContext.Connection.IOHandler.Write(List[I]);
  finally
    List.Free;
  end;
end;

procedure TFormMain.SendMessage(const IP, Msg: string); 
var 
  I: Integer; 
begin 
  with TCPServer.Contexts.LockList do 
  try 
    for I := 0 to Count-1 do 
    begin
      with TMyContext(Items[I]) do
      begin
        if Binding.PeerIP = IP then 
        begin 
          AddMsgToQueue(Msg); 
          Break; 
        end;
      end; 
    end;
  finally 
    TCPServer.Contexts.UnlockList; 
  end; 
end;

Answer 2

使用OnExecute，如果你无事可做，请睡眠（）一段时间，比如10毫秒。每个连接都有自己的OnExecute处理程序，因此这只会影响每个连接。

Answer 3

Indy组件集旨在模拟网络连接上的阻止操作。您应该将所有代码封装在OnExecute事件处理程序中。这应该是更容易，因为大多数协议都以任何方式阻塞（发送命令，等待响应等）。

你显然不喜欢它的操作模式，你想要一些无阻碍的东西。您应该考虑使用专为您打算使用它而设计的组件套件：试试ICS套件！ ICS不使用线程，所有工作都在事件处理程序中完成。

Answer 4

在OnExecute处理程序中，您可以使用TEvent和TMonitor等线程通信方法等待客户端的数据。

TMonitor自Delphi 2009开始提供，并提供方法（Wait，Pulse和PulseAll）来发送/接收具有最低CPU使用率的通知。

Answer 5

我有类似的情况占用100％的CPU，它通过添加IdThreadComponent和

解决

void __fastcall TForm3::IdThreadComponent1Run(TIdThreadComponent *Sender)
{
    Sleep(10);
}

是不是？我不确定。

没有OnExecute事件的TCP服务器

5 个答案: