Question

语言：进步10.1C

我有一个Windows窗体，在其上我动态创建了许多小部件（在这种情况下为切换框）。我可以创建0到64个小部件的任何内容，具体取决于用户在当前集合中有多少个hickies。当用户从一个集合更改为另一个集合时，将根据需要删除或创建窗口小部件。表单将根据显示的小部件数量进行调整。

用户可以通过从菜单栏，工具栏或键盘快捷键中选择操作来检查任意数量的项目并对选中的项目执行某些处理。但我也希望用户能够右键单击一个小部件，这应该会弹出一个弹出式菜单，其中包含可以仅对一个单击项执行的操作，无论是否已选中。

就其本身而言，这非常简单。在过去，我通过在用户点击任何一个动态控件时弹出一个弹出菜单来完成这种事情（在其他语言中）。但是我很难在进行中做这件简单的事情：

我无法使用一个响应右键单击所有小部件的弹出菜单。我尝试创建一个弹出菜单，然后在创建每个动态窗口小部件时，我将其弹出菜单属性设置为此菜单。问题是菜单只能应用于一个小部件。一旦我将它分配给Widget1，我就无法将其分配给Widget2。这导致人们想到为每个小部件创建一个单独但相同的菜单。随着小部件被破坏和重新创建，这些菜单也将被破坏。在一个会话中，我将创建并销毁数百甚至数千个这些相同的菜单，而用户可能会使用其中一个或两次。或者完全没有。所以这对我来说似乎不是一个好选择。

我的下一个解决方案是创建一个单独的菜单，我可以以编程方式弹出，但所有以编程方式弹出菜单的尝试都失败了。我尝试过“MENU-DROP”菜单MyMenu和其他类似的东西，我不能为我的生活弄清楚如何做到这一点。我也发现很难搜索到这方面的信息。好像没有其他人曾经尝试过这种情况，而且很少有人问过这个问题，没有令人满意的答案。我怀疑这不可能做到。

在尝试所有这些事情的同时，我也遇到了无数问题：MOUSE-MENU-DOWN，MOUSE-MENU-UP和MOUSE-MENU-CLICK。 MOUSE-MENU-CLICK似乎永远不会发生，不管怎么说都不是我的动态小部件。我无法弄清楚原因。 MOUSE-MENU-UP有时会出现，但它取决于MOUSE-MENU-DOWN中发生的事情以及小部件的其他事件以及小部件的父母。我无法确切知道它何时会发生或不发射，这是非常反直觉的。 MOUSE-MENU-DOWN是唯一可以指望射击的人。

所以：我无法以编程方式显示菜单，我只能通过右键单击菜单的父级来显示它。避免拥有数百个相同菜单的唯一方法是在窗口小部件的父窗口上设置一个弹出菜单，例如默认框架。

使用默认框架上的静态弹出菜单，我可以右键单击小部件，然后会出现菜单，但是如果我单击框架中的任何位置，它就会出现。我可以禁用菜单，然后在窗口小部件的右键单击事件中启用它。这是第一次非常好用;如果我点击框架中的任何地方，没有任何反应（菜单被禁用），但如果我点击我的小部件，菜单将启用并弹出。好极了！但现在菜单已启用，现在如果我右键单击任何位置，按钮，空白区域，进度条等，它会弹出。我什么时候再次禁用它？弹出菜单后，用户可以点击任意位置，菜单就会消失。

，当菜单关闭时，没有任何事件会触发

很抱歉长篇大论，我将简要地重述一下这个问题：当用户右键单击一些动态创建的小部件时，我想弹出一个弹出菜单。

使用Tom的答案，我就是这样做的：

/* Somewhere in Control Definitions... */
DEFINE MENU m_Popup 
       MENU-ITEM m_Test1     LABEL "Test 1"       
       MENU-ITEM m_Test2     LABEL "Test 2".     

/* Somewhere, where I need to dynamically create the widgets. */
/* Loop through the items in the temp table and create a widget for each. */
FOR EACH ttItem BY ttItem.ItemName:
  CREATE TOGGLE-BOX hWidget
    ASSIGN 
           FRAME        = FRAME DEFAULT-FRAME:HANDLE
           LABEL        = STRING(ttItem.ttItemName)
    TRIGGERS:
      ON MOUSE-MENU-DOWN PERSISTENT RUN GetMenu IN THIS-PROCEDURE.
    END TRIGGERS.
END.

/* If the user right-clicks on any one of the widgets, this procedure */
/* is run with SELF being the widget that was clicked on. */
PROCEDURE GetMenu:
  /* Remove the menu from its current owner and assign it to SELF. */
  MENU m_Popup:OWNER:POPUP-MENU = ?.
  SELF:POPUP-MENU = MENU m_Popup:HANDLE.
END PROCEDURE.

/* The user clicks on one of the menu items  */
/* Here SELF is the menu item that was clicked. I can */
/* get m_Popup from SELF:PARENT and the widget it was */
/* was assigned to from SELF:PARENT:OWNER.            */
ON CHOOSE OF MENU-ITEM m_Test1 
DO:
  MESSAGE "You selected " SELF:LABEL " for " SELF:PARENT:OWNER:LABEL.
END.

Answer 1

我的好友Mike Fechner（他目前没有参与SO，但是他比我做的更多）告诉我，虽然这个例子是静态的，但非常相似的东西应该有用：

Procedure getMenu:

  DEFINE INPUT PARAMETER phWidget AS HANDLE NO-UNDO.
  DO WITH FRAME {&FRAME-NAME}:
      FILL-IN-1:POPUP-MENU = ? .
      FILL-IN-2:POPUP-MENU = ? .
      FILL-IN-3:POPUP-MENU = ? .
  END.

  phWidget:POPUP-MENU = MENU POPUP-MENU-FILL-IN-1:HANDLE  .

END procedure.

在所有三个填充物的正确鼠标中，你“运行getMenu（SELF）”。从任何人那里窃取弹出菜单。

如何以编程方式操作正在进行中的多个动态窗口小部件上的弹出菜单

1 个答案: