Question

我的报告中有一个备忘录对象，需要替换“％...％”字符串。例如，在Rave报告中：

MemoBuf.ReplaceAll('%my_str%',  "new string", false);

但是，FastReport中不存在替换文本的方法（或属性）。我怎么能这样做？

我正在使用Fast Report 4.9.72和Delphi 2010。

谢谢！

Answer 1

由于FastReport中没有StringReplace，我可以从Delphi代码中完成。有可能以某种方式导入函数，但这似乎更好地安排。请注意，在第一个示例中，我认为Memo1存在（否则会出现访问冲突）。

procedure TForm1.Button1Click(Sender: TObject);
var
  Memo: TfrxMemoView;
begin
  Memo := frxReport1.FindObject('Memo1') as TfrxMemoView;
  Memo.Text := StringReplace(Memo.Text, '%my_str%', 'new string', [rfReplaceAll]);
  frxReport1.ShowReport;
end;

如果您不确定组件名称或类型，则应使用以下内容：

procedure TForm1.Button2Click(Sender: TObject);
var
  Memo: TfrxMemoView;
  Component: TfrxComponent;
begin
  Component := frxReport1.FindObject('Memo1');
  if Component is TfrxMemoView then
  begin
    Memo := Component as TfrxMemoView;
    Memo.Text := StringReplace(Memo.Text, '%my_str%', 'new string', [rfReplaceAll]);
    frxReport1.ShowReport;
  end;
end;

Answer 2

我不知道Rave Reports中该代码的用途是什么，因为我从未使用它，但我可以为FastReport提出替代方案：

快速报告所有Memo的支持变量替换。设置名为“my_str”的报告变量，编辑备忘录并包含变量。备忘录中的文字如下所示：[my_str]。这可能是最好的选择。这些括号的内容实际上是一个完整的pascal表达式，可以使用数据集字段，报表变量，注册函数。您甚至可以编写Delphi函数，使用FastReport注册它并在[..]内调用它，从数据集中传递一个字段作为参数。可能性真是无穷无尽。
FastReport备忘录可以从Delphi端进行操作，因此您可以使用任何想要更改备忘录文本的功能。
也可以从项目的脚本（从报告中，而不是从Delphi中）操作备忘录，也可以做任何你需要做的事情。

Answer 3

您可以在快速报告中使用此代码：

function StringReplace(const S, OldPattern, NewPattern: string;
  iReplaceAll: boolean=true; iIgnoreCase :boolean=true): string;
var
  SearchStr, Patt, NewStr: string;
  Offset: Integer;
begin
  if iIgnoreCase then begin
    SearchStr := UpperCase(S);
    Patt := UpperCase(OldPattern);
  end else begin
    SearchStr := S;
    Patt := OldPattern;
  end;
  NewStr := S;
  Result := '';
  while SearchStr <> '' do begin
    Offset := Pos(Patt, SearchStr);
    if Offset = 0 then begin
      Result := Result + NewStr;
      Break;
    end;
    Result := Result + Copy(NewStr, 1, Offset - 1) + NewPattern;
    NewStr := Copy(NewStr, Offset + Length(OldPattern), MaxInt);
    if not iReplaceAll then begin
      Result := Result + NewStr;
      Break;
    end;
    SearchStr := Copy(SearchStr, Offset + Length(Patt), MaxInt);
  end;
end;

如何替换备忘录中的字符串（FastReport）？

3 个答案: