Question

将yyyymmddhhmmss转换为YYYY-MM-DD的最佳方法是什么？hh：mm：ss并返回perl？

例如：20130218165601到2013-02-18 16:56:01又回来了？（https://metacpan.org/module/Rose::DateTime可以这样做吗？

没有正则表达式，如果可能的话;）

Answer 1

这个模块太过分了。

# Packed -> ISO
(my $iso_date = $packed_date) =~
   s/^(....)(..)(..)(..)(..)(..)\z/$1-$2-$3 $4:$5:$6/s;

# ISO -> Packed
(my $packed_date = $iso_date) =~
   s/^(....)-(..)-(..) (..):(..):(..)\z/$1$2$3$4$5$6/s;

Rose::DateTime无法按预期解析“压缩”格式，但您可以使用DateTime::Format::Strptime。

use DateTime::Format::Strptime qw( );
my $packed_format = DateTime::Format::Strptime->new(
   pattern  => '%Y%m%d%H%M%S',
   on_error => 'croak',
);
my $iso_format = DateTime::Format::Strptime->new(
   pattern  => '%Y-%m-%d %H:%M:%S',
   on_error => 'croak',
);

# Packed -> ISO
my $iso_date = $iso_format->format_datetime(
   $packed_format->parse_datetime($packed_date)
);

# ISO -> Packed
my $packed_date = $packed_format->format_datetime(
   $iso_format->parse_datetime($iso_date)
);

Answer 2

使用sprintf快速解决方案。

my $date = sprintf "%s%s-%s-%s %s:%s:%s", $string =~ /(..)/g;

然后回来：

my $foo = join '', $date =~ /\d+/g;

Answer 3

没有正则表达式，您只需使用substr来抓取所需的字符：

$year  = substr $d, 0, 4;
$month = substr $d, 4, 2;
...
$secs  = substr $d, 12, 2;

yyyymmddhhmmss到YYYY-MM-DD hh：mm：ss in perl？

3 个答案: