Question

我正在寻找一种方法将以下代码缩减为单个regexp语句：

if( $current_value =~ /(\d+)(MB)*/ ){
        $current_value = $1 * 1024 * 1024;
    }
    elsif( $current_value =~ /(\d+)(GB)*/ ){
        $current_value = $1 * 1024 * 1024 * 1024;
    }
    elsif( $current_value =~ /(\d+)(KB)*/ ){
        $current_value = $1 * 1024;
    }

代码执行值的评估，可以表示为单个数字（字节），数字和KB（千字节），兆字节（MB）等。关于如何减少块代码的任何想法？

Answer 1

Number::Format

use warnings;
use strict;

use Number::Format qw(format_bytes);
print format_bytes(1024), "\n";
print format_bytes(2535116549), "\n";

__END__

1K
2.36G

Answer 2

您可以设置这样的哈希：

my %FACTORS = ( 'KB' => 1024, 'MB' => 1024**2, 'GB' => 1024**3 );

然后像这样解析文本：

if ( $current_value =~ /(\d+)(KB|MB|GB)/ ) {
    $current_value = $1 * $FACTORS{$2};
}

在您的示例中，正则表达式具有*我不确定您的意图，因为*表示“零或更多”，因此(+\d)(MB)*将匹配10或10MB或10MBMB或10MBMBMBMBMBMBMB。

Answer 3

使用benzado的修改代码，这是一个可以运行的测试，看看它是否有效。

我们建议您始终将这样的代码放在一个可重用的方法中，然后为它编写一个小的单元测试：

use Test::More;

plan tests => 4;

##
# Convert a string denoting '50MB' into an amount in bytes.
my %FACTORS = ( 'KB' => 1024, 'MB' => 1024*1024, 'GB' => 1024*1024*1024 );
sub string_to_bytes {
        my $current_value = shift;

        if ( $current_value =~ /(\d+)(KB|MB|GB)/ ) {
            $current_value = $1 * $FACTORS{$2};
        }
        return $current_value;
}

my $tests = {
        '50' => 50,
        '52KB' => 52*1024,
        '55MB' => 55*1024*1024,
        '57GB' => 57*1024*1024*1024
};

foreach(keys %$tests) {
        is( string_to_bytes($_),$tests->{$_},
            "Testing if $_ becomes $tests->{$_}");
}

运行此命令：

$ perl testz.pl
1..4
ok 1 - Testing if 55MB becomes 57671680
ok 2 - Testing if 50 becomes 50
ok 3 - Testing if 52KB becomes 53248
ok 4 - Testing if 57GB becomes 61203283968

现在你可以

添加更多的测试用例（大数字会发生什么？你想要发生什么？对于字符串，当你用小k写小写字母时，遇到kibiB或kiB或Kb时，对于字符串是什么？）
将其变为模块
在POD中编写文档
将模块上传到CPAN

瞧！

Answer 4

您可以在 one regexp中执行此操作，方法是将代码片段和放在正则表达式中，以区别对待这三种情况

my $r; $current_value =~ s/ (\d+)(?: Ki (?{ $r = $^N * 1024 }) | Mi (?{ $r = $^N * 1024 * 1024 }) | Gi (?{ $r = $^N * 1024 * 1024 * 1024 }) )/$r/xso;

Answer 5

将KB用于1024字节时出现问题。 Kilo作为前缀通常意味着1000不是1024。

问题因MB而变得更糟，因为它意味着1000*1000，1024*1024和1000*1024。

1.44 MB软盘实际上持有1.44 * 1000 * 1024。

唯一真正的方法是使用新的KiB（Kibibyte）来表示1024字节。

您实施它的方式还有一个限制，即您无法使用8.4Gi来表示8.4 * 1024 * 1024。要删除该限制，我使用Regexp::Common中的$RE{num}{real}代替\d+。

其他一些答案通过写出所有可能的比赛来硬连线。这可能变得非常繁琐，更不用说容易出错了。为了解决这个问题，我使用了%multiplier的键来生成正则表达式。这意味着如果您添加或删除%multiplier中的元素，则无需手动修改正则表达式。

use strict;
use warnings;
use Regexp::Common;

my %multiplier;
my $multiplier_match;
{

  # populate %multiplier
  my %exponent = (
    K => 1, # Kilo  Kibi
    M => 2, # Mega  Mebi 
    G => 3, # Giga  Gibi
    T => 4, # Tera  Tebi
    P => 5, # Peta  Pebi
    E => 6, # Exa   Exbi
    Z => 7, # Zetta Zebi
    Y => 8, # Yotta Yobi
  );
  while( my ($str,$exp) = each %exponent ){
    @multiplier{ $str,      "${str}B"  } = (1000 ** $exp) x2; # K  KB
    @multiplier{ "${str}i", "${str}iB" } = (1024 ** $exp) x2; # Ki KiB
  }
  # %multiplier now holds 32 pairs (8*4)

  # build $multiplier_match
  local $" #" # fix broken highlighting
    = '|';
  my @keys = keys %multiplier;
  $multiplier_match = qr(@keys);

}

sub remove_multiplier{
  die unless @_ == 1;
  local ($_) = @_;

  #  s/^($RE{num}{real})($multiplier_match)$/ $1 * $multiplier{$2} /e;
  if( /^($RE{num}{real})($multiplier_match)$/ ){
    return $1 * $multiplier{$2};
  }

  return $_;
}

如果你绝对需要1K来表示1024，那么你只需要换一行。

# @multiplier{ $str, "${str}B"  } = (1000 ** $exp) x2; # K  KB
  @multiplier{ $str, "${str}B"  } = (1024 ** $exp) x2; # K  KB

请注意，由于我使用Regexp::Common中的$RE{num}{real}，因此它也适用于5.3e1Ki。

获取用存储器单元表示的值的perl方式

5 个答案: