Question

您能帮我解决一下如何在PL / SQL中为存储过程创建二维数组？列是动态的，因此它也可以增长和改变类型。任何帮助表示赞赏。提前谢谢！

我有以下代码：

Type CAR_TABLE_ARRAY is varray(2) of varchar2(255);
TYPE CAR_TABLE_TYPE IS TABLE OF CAR_TABLE_ARRAY;
CAR_TABLE CAR_TABLE_TYPE;

CAR_TABLE := CAR_TABLE_TYPE();
CAR_TABLE.EXTEND(10);
CAR_TABLE(1)(1) := 'DODGE';
CAR_TABLE(2)(1) := 'FORD';
CAR_TABLE(3)(1) := 'MUSTANG';
CAR_TABLE(4)(1) := 'EDSEL';
CAR_TABLE(5)(1) := 'STUDEBAKER';

DBMS_OUTPUT.put_line( '1 ' || CAR_TABLE(1)(1) );
DBMS_OUTPUT.put_line( '2 ' || CAR_TABLE(2)(1) );
DBMS_OUTPUT.put_line( '3 ' || CAR_TABLE(3)(1) );
DBMS_OUTPUT.put_line( '4 ' || CAR_TABLE(4)(1) );
DBMS_OUTPUT.put_line( '5 ' || CAR_TABLE(5)(1) );

当我跑步时，我收到以下错误：

ORA-06531：未初始化集合的参考

Answer 1

这是在pl / sql中使用多维数组的示例。这里我使用一个包含数组的数组。

declare

  type t_features is table of varchar(100) index by pls_integer;
  type t_car_rec is record
  (
    make varchar2(50),
    model varchar2(50),
    features t_features
  );

  type t_car_tab is table of t_car_rec index by pls_integer;
  car_tab t_car_tab;

  procedure show_detail is
    car_idx pls_integer;
    features_idx pls_integer;
  begin
    car_idx := car_tab.first;
    loop
      exit when car_idx is null;
      dbms_output.put_line('Details for ' || car_tab(car_idx).make || ' ' || car_tab(car_idx).model);

      features_idx := car_tab(car_idx).features.first;
      loop
        exit when features_idx is null;
        dbms_output.put_line('   =>' || car_tab(car_idx).features(features_idx));

        features_idx := car_tab(car_idx).features.next(features_idx);
      end loop;

      car_idx := car_tab.next(car_idx);
    end loop;
  end;

begin

  -- using sequential index values
  car_tab(1).make := 'Ferrari';
  car_tab(1).model := 'Testarossa';
  car_tab(1).features(1) := 'Fast';
  car_tab(1).features(2) := 'Looks cool';
  car_tab(1).features(3) := 'Expensive';

  -- using random index values (sparse)
  car_tab(2).make := 'Acura';
  car_tab(2).model := 'TSX';
  car_tab(2).features(14) := 'Small';
  car_tab(2).features(200) := 'Good MPG';
  car_tab(2).features(36) := 'Inexpensive';

  show_detail;

end;

输出将是：

Details for Ferrari Testarossa
  =>Fast
  =>Looks cool
  =>Expensive 
Details for Acura TSX
  =>Small
  =>Inexpensive
  =>Good MPG

希望有所帮助

Answer 2

VARRAY和嵌套表用户定义的数据类型始终必须使用构造函数进行初始化。您正在为嵌套表正确地执行此操作，但不适用于它包含的VARRAY。最简单的解决方法是在赋值行中调用构造函数：

declare
    Type CAR_TABLE_ARRAY is varray(2) of varchar2(255);
    TYPE CAR_TABLE_TYPE IS TABLE OF CAR_TABLE_ARRAY;
    CAR_TABLE CAR_TABLE_TYPE;
begin    
    CAR_TABLE := CAR_TABLE_TYPE();
    CAR_TABLE.EXTEND(10);
    CAR_TABLE(1) := CAR_TABLE_ARRAY('DODGE',null);
    CAR_TABLE(2) := CAR_TABLE_ARRAY('FORD',null);
    CAR_TABLE(3) := CAR_TABLE_ARRAY('MUSTANG',null);
    CAR_TABLE(4) := CAR_TABLE_ARRAY('EDSEL',null);
    CAR_TABLE(5) := CAR_TABLE_ARRAY('STUDEBAKER',null);

    DBMS_OUTPUT.put_line( '1 ' || CAR_TABLE(1)(1) );
    DBMS_OUTPUT.put_line( '2 ' || CAR_TABLE(2)(1) );
    DBMS_OUTPUT.put_line( '3 ' || CAR_TABLE(3)(1) );
    DBMS_OUTPUT.put_line( '4 ' || CAR_TABLE(4)(1) );
    DBMS_OUTPUT.put_line( '5 ' || CAR_TABLE(5)(1) );
end;

Answer 3

那是因为你引用了未初始化的内部数组添加如下内容：

CAR_TABLE(1) := CAR_TABLE_ARRAY();
CAR_TABLE(1).EXTEND(1);
CAR_TABLE(2) := CAR_TABLE_ARRAY();
CAR_TABLE(2).EXTEND(1);
...

或者将内部数组（CAR_TABLE_ARRAY）作为非关联数组：

Type CAR_TABLE_ARRAY is TABLE of varchar2(255) index by binary_integer;

在PL / SQL中创建或模拟二维数组

3 个答案: