Delphi XE2：在组件上禁用vcl Style

Question

我正在尝试按照示例禁用表单上控件的颜色。

TStyleManager.Engine.RegisterStyleHook（ClrMeans.TwwDBComboDLG，TEditStyleHook）;

但是，当注册或取消注册第三方控件（infopower TwwDBComboDlg）或标准VCL TEdit时，我会收到异常。任何人对此或任何建议都有任何问题

Answer 1

此处link解释了您需要了解的内容。

基本上，您需要在其中放置一个“空挂钩”，这是您已经知道的，或者您需要将“VCL颜色”挂钩，这是您所缺少的一半。另一半是你的零指针问题。

要使TEdit衍生物（与您的一样）看起来像VCL标准颜色，您需要使用它来控制您的控件的代码是：

uses
  Winapi.Messages,
  Vcl.Controls,
  Vcl.StdCtrls,
  Vcl.Forms,
  Vcl.Themes,
  Vcl.Styles;

type

TEditStyleHookColor = class(TEditStyleHook)
  private
    procedure UpdateColors;
  protected
    procedure WndProc(var Message: TMessage); override;
    constructor Create(AControl: TWinControl); override;
  end;

implementation


type
 TWinControlH= class(TWinControl);


constructor TEditStyleHookColor.Create(AControl: TWinControl);
begin
  inherited;
  //call the UpdateColors method to use the custom colors
  UpdateColors;
end;

//Here you set the colors of the style hook
procedure TEditStyleHookColor.UpdateColors;
var
  LStyle: TCustomStyleServices;
begin
 if Control.Enabled then
 begin
  Brush.Color := TWinControlH(Control).Color; //use the Control color
  FontColor   := TWinControlH(Control).Font.Color;//use the Control font color
 end
 else
 begin
  //if the control is disabled use the colors of the style
  LStyle := StyleServices;
  Brush.Color := LStyle.GetStyleColor(scEditDisabled);
  FontColor := LStyle.GetStyleFontColor(sfEditBoxTextDisabled);
 end;
end;

//Handle the messages of the control
procedure TEditStyleHookColor.WndProc(var Message: TMessage);
begin
  case Message.Msg of
    CN_CTLCOLORMSGBOX..CN_CTLCOLORSTATIC:
      begin
        //Get the colors
        UpdateColors;
        SetTextColor(Message.WParam, ColorToRGB(FontColor));
        SetBkColor(Message.WParam, ColorToRGB(Brush.Color));
        Message.Result := LRESULT(Brush.Handle);
        Handled := True;
      end;
    CM_ENABLEDCHANGED:
      begin
        //Get the colors
        UpdateColors;
        Handled := False;
      end
  else
    inherited WndProc(Message);
  end;
end;

Procedure ApplyVCLColorsStyleHook(ControlClass :TClass);
begin
    if Assigned(TStyleManager.Engine) then
       TStyleManager.Engine.RegisterStyleHook(ControlClass, TEditStyleHookColor);
end;

initialization
     ApplyVCLColorsStyleHook(TwwDBComboDlg);

你对NIL的问题是，如果你没有打开VCL主题，那么Engine就是nil，你应该检查并从该代码返回而不调用你正在调用的那个函数。在这里您可以打开主题，以防错过它：

有趣的一面：获取the VCL Styles utils图书馆。以下是使用它来更改内容颜色的示例：

 TCustomStyleExt(TStyleManager.ActiveStyle).SetStyleColor(scEdit, clWindow);
 TCustomStyleExt(TStyleManager.ActiveStyle).SetStyleFontColor(sfEditBoxTextNormal
                   ,clWindowText);

您可以创建样式，并将这些样式应用于特定控件，甚至可以扩展主题引擎，也可以使用VCL样式实用工具来获得所需的结果，但这不会是微不足道的。