Question

我有一个非常简单的分类法，我正在freemind中进行编辑，并希望将它在protovis中可视化为sunburst可视化。分类的深度是未知的。

我已经尝试构建一个XLST转换，可以通过xsl脚本功能与Freemind的导出一起使用 - 以Protovis生成sunburst所需的精确JSON格式输出数据 - 这个想法是不需要进一步转换在javascript。

我正在寻找的输出JSON格式的示例如下： http://mbostock.github.com/protovis/ex/sunburst.html

有效地，freemind .mm文件格式是输入。

在stylus studio中运行我的alpha代码（如下所示）会构建一个json格式（格式错误但看起来合法），当我将手写笔工作室生成的输出直接手动保存到.js文件时，可以提供protovis。出于某种原因，Freemind似乎不使用此代码导出数据......

有什么我想念的吗？任何帮助表示赞赏。

非常感谢，安德鲁

=========== UPDATE =============

我已经更正了代码，问题是freemind使用的xslt引擎不支持我的某些xsl。我更正了代码，并在自由许可下将其移至github并从此处删除。

适配器可在此处获得： https://github.com/minkymorgan/Freemind2JSON#readme

安德鲁

Answer 1

这是我的尝试。我根据您的版本，添加了一些功能。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/map">
        <xsl:text>var Map = {
</xsl:text>
        <xsl:apply-templates select="node">
            <xsl:with-param name="indent">
                <xsl:text>    </xsl:text>
            </xsl:with-param>
        </xsl:apply-templates>
        <xsl:text>
};
</xsl:text>
    </xsl:template>

    <xsl:template match="node">
        <xsl:param name="indent"/>
        <xsl:if test="position() != 1">
            <xsl:text>,
</xsl:text>
        </xsl:if>
        <xsl:value-of select="$indent"/>
        <xsl:text>"</xsl:text>
        <xsl:call-template name="escape-javascript">
            <xsl:with-param name="string"
                select="descendant-or-self::node/@TEXT"/>
        </xsl:call-template>
        <xsl:text>": </xsl:text>
        <xsl:choose>
            <xsl:when test="node">
                <xsl:text>{
</xsl:text>
                <xsl:apply-templates select="node">
                    <xsl:with-param name="indent">
                        <xsl:value-of select="$indent"/>
                        <xsl:text>    </xsl:text>
                    </xsl:with-param>
                </xsl:apply-templates>
                <xsl:text>
</xsl:text>
                <xsl:value-of select="$indent"/>
                <xsl:text>}</xsl:text>
            </xsl:when>
            <xsl:otherwise>
                <xsl:text>10</xsl:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <!--
        Javascript string escape template by Jeni Tennison
        Source: http://holytshirt.blogspot.com/2008/06/xslt-javascript-escaping.html
        Author page: http://www.jenitennison.com/
    -->
    <xsl:template name="escape-javascript">
        <xsl:param name="string" />
        <xsl:choose>
            <xsl:when test='contains($string, "&apos;")'>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select='substring-before($string, "&apos;")' />
                </xsl:call-template>
                <xsl:text>\'</xsl:text>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select='substring-after($string, "&apos;")' />
                </xsl:call-template>
            </xsl:when>
            <xsl:when test="contains($string, '&#xA;')">
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select="substring-before($string, '&#xA;')" />
                </xsl:call-template>
                <xsl:text>\n</xsl:text>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select="substring-after($string, '&#xA;')" />
                </xsl:call-template>
            </xsl:when>
            <xsl:when test="contains($string, '\')">
                <xsl:value-of select="substring-before($string, '\')" />
                <xsl:text>\\</xsl:text>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select="substring-after($string, '\')" />
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise><xsl:value-of select="$string" /></xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

如果在Freemind test file上运行，则会产生以下输出：

var Map = {
    "Notetest": {
        "Notetest": 10,
        "This is a node": {
            "with a linbreak \n subnode": 10,
            "and another subnode": 10,
            "and some folded subnodes": {
                "fold1": 10,
                "fold2": 10,
                "fold3": 10
            }
        },
        "Attributes": 10
    }
};

Answer 2

如果感兴趣的话......我刚刚推出了一个XSLT脚本，用于将FreeMind转换为JSON。我的脚本有点简单，还不支持Javascript转义。

它也不是为Protovis设计的

https://github.com/tohagan/freemind-to-json

Freemind到JSON到Protovis xslt转换草案

2 个答案: