Question

请考虑下面的脚本，即使$ b是部分匹配，我也要将$ b与$ a匹配。可以这样做吗？

$a="MCF-7";
$b="MCF";
if($b=~m/$a/i)
{
    print "FOUND";
}

Answer 1

虽然正则表达式可以执行此操作，但听起来您的问题也可以通过index函数解决：

say index($haystack, $needle) >= 0 ? 'match' : 'fail'; # any position
say index($haystack, $needle) == 0 ? 'match' : 'fail'; # anchored at start

index函数区分大小写。如果您想要不敏感的匹配，请将uc或lc函数应用于这两个参数。

虽然index函数比正则表达式快得多，但如果你想要一个正则表达式解决方案，你可以构建一个正则表达式生成器，它产生一系列将执行部分匹配的替换。

sub build_partial {
    my ($str, $min) = (@_, 1);
    my @re;
    for (0 .. length($str) - $min) {
        my $str = substr $str, $_;
        for ($min .. length $str) {
            push @re, quotemeta substr $str, 0, $_
        }
    }
    my $re = join '|' => sort {length $a <=> length $b} @re;
    qr/^(?:$re)$/i
}

my $haystack = 'MCF-7';
my $needle   = 'MCF';

my $regex = build_partial $haystack;

say $needle =~ /$regex/ ? 'match' : 'fail'; # match

为MCF-7生成的正则表达式如下所示：

/^(?:M|C|F|7|MC|CF|\-|MCF|F\-|\-7|CF\-|F\-7|MCF\-|CF\-7|MCF\-7)$/i

即使针是大海捞针中的单个字符，它也会匹配。 build_partial采用可选数字表示匹配所需的最小长度：

my $regex_3 = build_partial $haystack, 3;

产生这个正则表达式：

/^(?:MCF|CF\-|F\-7|MCF\-|CF\-7|MCF\-7)$/i

这些模式匹配从任何位置开始的子字符串。如果您希望它锚定在字符串的前面，build_partial会变得更简单：

sub build_partial {
    my ($str, $min) = (@_, 1);

    my $re = join '|' => map {
        quotemeta substr $str, 0, $_
    } $min .. length $str;

    qr/^(?:$re)$/i
}

Answer 2

您似乎已将$a和$b混为一谈：

use strict;
use warnings;
my $a="MCF-7";
my $b="MCF";
if($a=~/$b/i) #tests for case-insensitive matching of $b within $a.
{
 print "Found\n";
}

您问题中的代码没有产生任何输出，因为"MCF-7"内的"MCF"不匹配。

Perl部分匹配

2 个答案: