Question

假设我有一个简单的XML文件：

<data>
  <text>Hello world!&lt;br&gt;Nice to see you all!&lt;br&gt;Goodbye!</text>
</data>

现在我想用<br>字符串替换所有
字符串，结果应该是例如：

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

我该怎么做？

XSL替换功能很容易实现（例如在http://geekswithblogs.net/Erik/archive/2008/04/01/120915.aspx中），但棘手的部分是让XSL转换器输出那些
字符串..我要么得到不可见的正常换行符，要么{{1 }}

完美的答案将是一个XSL模板，它可以解决问题。

Answer 1

使用：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/data">
    <transformed>
      <text>
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="text" />
          <xsl:with-param name="replace">&lt;br&gt;</xsl:with-param>
          <xsl:with-param name="by">&amp;#10;</xsl:with-param>
        </xsl:call-template>
      </text>
    </transformed>
  </xsl:template>

  <xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
      <xsl:when test="contains($text, $replace)">
        <xsl:value-of select="substring-before($text, $replace)" />
        <xsl:value-of select="$by" disable-output-escaping="yes" />
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="substring-after($text,$replace)" />
          <xsl:with-param name="replace" select="$replace" />
          <xsl:with-param name="by" select="$by" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

输出：

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

NB：

将disable-output-escaping属性设为yes

如何用。替换br标签 XSL模板中的标签？

1 个答案:

NB：