Question

所以，我想做的事情应该很简单。它只是一个翻转动画，当用户将鼠标滚开时会反转。事情是，它在AS2，但我认为完成项目我将在AS3中需要它。任何人都可以提出一些转换此建议的建议......

stop();

this.onEnterFrame = function(){
if(rewind == true){
prevFrame();
}
}

this.onRollOver = function(){
rewind = false;
play();
}

this.onRollOut = function(){
rewind = true;
}

this.onRelease = function(){
getURL("http://www.google.com","_blank");
}

...进入AS3？我会非常感激。

Answer 1

如果您的代码需求仅限于这些，您应该一劳永逸地学习如何在AS3中完成。

这与AS3中的完全相同

import flash.events.Event;
import flash.events.MouseEvent;
import flash.net.navigateToURL;
import flash.net.URLRequest;

stop();
addEventListener(Event.ENTER_FRAME, onEnterFrame);
addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
addEventListener(MouseEvent.MOUSE_OUT, onMouseOut);
addEventListener(MouseEvent.CLICK, onClick);

var rewind:Boolean = false;

function onEnterFrame(event:Event):void
{
    if (rewind == true) {
        prevFrame();
    }
}

function onMouseOver(event:MouseEvent):void
{
    rewind = false;
    play();
}

function onMouseOut(event:MouseEvent):void
{
    rewind = true;
}

function onClick(event:MouseEvent):void
{
    navigateToURL(new URLRequest("http://www.google.com"),"_blank");
}

请注意，不是通过编写this.onRollOver = function()来创建事件的监听器（例如翻转），而是实际上必须调用addEventListener（这是非常合理的），指定您想要的事件收听并创建捕获此事件时调用的函数。

getURL - ＆gt; navigateToURL还有另一个区别，但我认为您无需进一步解释：）

谢天谢地，我非常感谢您阅读此代码并尝试从中学习，而不是粗略地复制/粘贴它。但是，嘿，你有空！

将基本ActionScript 2转换为ActionScript 3以进行翻转动画

1 个答案: