Question

我修改了MSDN示例以反映我的问题。

当使用命名空间时，我无法像我期望的那样获得文档验证，并且在验证没有命名空间的文档时，无论是否有错误，它都会验证。

Dim errors As Boolean = False

Private Sub XSDErrors(ByVal o As Object, ByVal e As ValidationEventArgs)
    Console.WriteLine("{0}", e.Message)
    errors = True
End Sub

Private Function AddNameSpace(ByVal xDoc As XDocument, ByVal ns As XNamespace) As XDocument
    For Each element As XElement In xDoc.Descendants
        element.Name = ns + element.Name.LocalName
    Next
    Return xDoc
End Function

Sub Main()
    Dim xsdMarkup As XElement = _
        <xsd:schema xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns="http://somenamespace.com" targetNamespace="http://somenamespace.com">
            <xsd:element name='Root'>
                <xsd:complexType>
                    <xsd:sequence>
                        <xsd:element name='Child1' minOccurs='1' maxOccurs='1'/>
                        <xsd:element name='Child2' minOccurs='1' maxOccurs='1'/>
                    </xsd:sequence>
                </xsd:complexType>
            </xsd:element>
        </xsd:schema>
    Dim schemas As XmlSchemaSet = New XmlSchemaSet()
    schemas.Add("http://somenamespace.com", xsdMarkup.CreateReader)

    Dim doc1 As XDocument = _
        <?xml version='1.0'?>
        <Root>
            <Child1>content1</Child1>
            <Child2>content1</Child2>
        </Root>

    Dim doc2 As XDocument = _
        <?xml version='1.0'?>
        <Root>
            <Child1>content1</Child1>
            <Child3>content1</Child3>
        </Root>

    Dim ns As XNamespace = "http://somenamespace.com"
    doc1 = AddNameSpace(doc1, ns)

    Console.WriteLine("Validating doc1")
    errors = False
    doc1.Validate(schemas, AddressOf XSDErrors)
    Console.WriteLine("doc1 {0}", IIf(errors = True, "did not validate", "validated"))

    Console.WriteLine()
    Console.WriteLine("Validating doc2")
    errors = False
    doc2.Validate(schemas, AddressOf XSDErrors)
    Console.WriteLine("doc2 {0}", IIf(errors = True, "did not validate", "validated"))

End Sub

输出：

验证doc1

名称空间“http://somenamespace.com”中的元素“Root”在名称空间“http://somenamespace.com”中具有无效的子元素“Child1”。预期可能元素列表：'Child1'。

doc1未验证

验证doc2

doc2验证

Answer 1

如果您希望elementFormDefault="qualified"将每个元素上的命名空间置于有效状态，则需要将xsd:schema添加到模式（doc1元素）。对于当前架构，有效实例将是Root在targetNamespace中但ChildX元素不在命名空间中的实例。

第二个问题是模式验证和命名空间的已知问题，验证解析器会查找根元素的匹配模式，如果没有，它会进行松散验证，因此您不会收到验证错误。使用XmlReader API，您可以要求在这种情况下发出警告，但我不知道如何使用Validate方法执行此操作。所以你需要像

这样的代码

Imports System
Imports System.Xml
Imports System.Xml.Linq
Imports System.Xml.Schema

Module Module1

    Dim errors As Boolean = False

    Private Sub XSDErrors(ByVal o As Object, ByVal e As ValidationEventArgs)
        Console.WriteLine("{0}", e.Message)
        errors = True
    End Sub

    Private Function AddNameSpace(ByVal xDoc As XDocument, ByVal ns As XNamespace) As XDocument
        For Each element As XElement In xDoc.Descendants
            element.Name = ns + element.Name.LocalName
        Next
        Return xDoc
    End Function

    Sub Main()
        Dim xsdMarkup As XElement = _
            <xsd:schema xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns="http://somenamespace.com" targetNamespace="http://somenamespace.com" elementFormDefault="qualified">
                <xsd:element name='Root'>
                    <xsd:complexType>
                        <xsd:sequence>
                            <xsd:element name='Child1' minOccurs='1' maxOccurs='1'/>
                            <xsd:element name='Child2' minOccurs='1' maxOccurs='1'/>
                        </xsd:sequence>
                    </xsd:complexType>
                </xsd:element>
            </xsd:schema>
        Dim schemas As XmlSchemaSet = New XmlSchemaSet()
        schemas.Add("http://somenamespace.com", xsdMarkup.CreateReader)

        Dim doc1 As XDocument = _
            <?xml version='1.0'?>
            <Root>
                <Child1>content1</Child1>
                <Child2>content1</Child2>
            </Root>

        Dim doc2 As XDocument = _
            <?xml version='1.0'?>
            <Root>
                <Child1>content1</Child1>
                <Child3>content1</Child3>
            </Root>

        Dim ns As XNamespace = "http://somenamespace.com"
        doc1 = AddNameSpace(doc1, ns)

        Console.WriteLine("Validating doc1")
        errors = False
        doc1.Validate(schemas, AddressOf XSDErrors)
        Console.WriteLine("doc1 {0}", IIf(errors = True, "did not validate", "validated"))

        Console.WriteLine()
        Console.WriteLine("Validating doc2")
        Dim xrs As New XmlReaderSettings()
        xrs.ValidationType = ValidationType.Schema
        xrs.ValidationFlags = xrs.ValidationFlags Or XmlSchemaValidationFlags.ReportValidationWarnings
        xrs.Schemas = schemas
        AddHandler xrs.ValidationEventHandler, AddressOf XSDErrors
        errors = False
        Using xr1 As XmlReader = doc2.CreateReader()
            Using xr2 As XmlReader = XmlReader.Create(xr1, xrs)
                While xr2.Read()

                End While
            End Using
        End Using
        Console.WriteLine("doc2 {0}", IIf(errors = True, "did not validate", "validated"))

    End Sub

End Module

XDocument.Validate名称空间问题

1 个答案: