Question

下面是一个Haskell / C FFI代码，它在运行时抛出计划错误（GHC 7.0.3，Mac OS 10.7，x86_64）。我搜索了错误的解释，但没有发现任何相关内容。

C代码（mt.c）：

#include <pthread.h>
#include <stdio.h>

typedef void(*FunctionPtr)(int);

/* This is our thread function.  It is like main(), but for a thread*/
void *threadFunc(void *arg)
{
  FunctionPtr fn;
  fn = (FunctionPtr) arg;
  fn(1); //call haskell function with a CInt argument to see if it works
}

void create_threads(FunctionPtr* fp, int numThreads )
{
  pthread_t pth[numThreads];  // array of pthreads
  int t;
  for (t=0; t < numThreads;){
    pthread_create(&pth[t],NULL,threadFunc,*(fp + t));
    t++;
  }

  printf("main waiting for all threads to terminate...\n");
  for (t=0; t < numThreads;t++){
    pthread_join(pth[t],NULL);
  }
}

Haskell代码（t.hs） - 它在create_threads上面调用mt.c Storable Vector FunPtr到Haskell函数f（申请后） f）的前三个参数：

{-# LANGUAGE BangPatterns #-}
import Control.Concurrent (forkIO, threadDelay, MVar, newEmptyMVar, putMVar, takeMVar)
import qualified Data.Vector.Storable.Mutable as MSV
import qualified Data.Vector.Storable as SV
import Control.Monad.Primitive (PrimState)
import Control.Monad (mapM, forM_)
import Foreign.Ptr (Ptr, FunPtr)
import Foreign.C.Types (CInt)


type Length = CInt

-- | f is a function that is called back by create_threads in mt.c
f :: MVar Int -> MSV.MVector (PrimState IO) CInt -> Length -> CInt -> IO ()
f m v l x = do
              !i <- takeMVar m
              case (i< fromIntegral l) of
                True -> MSV.unsafeWrite v i x >> print x >> putMVar m (i+1) 
                False -> return () -- overflow

-- a "wrapper" import gives us a converter for converting a Haskell function to a foreign function pointer
foreign import ccall "wrapper"
  wrap :: (CInt -> IO()) -> IO (FunPtr (CInt -> IO()))

foreign import ccall safe "create_threads"
  createThreads :: Ptr (FunPtr (CInt -> IO())) -> CInt -> IO()

main = do
  let threads = [1..4]
  m <- mapM (\x -> newEmptyMVar) $ threads
  -- intialize mvars with 0
  forM_ m $ \x -> putMVar x 0
  let l = 10
  -- intialize vectors of length 10 that will be filled by function f
  v <- mapM (\x -> MSV.new l) threads
  -- create a list of function pointers to partial function - the partial function is obtained by applying first three arguments to         function f
  lf <- mapM (\(x,y) -> wrap (f x y (fromIntegral l))) $ zip m v
  -- convert above function list to a storable vector of function pointers
  let fv = SV.fromList lf
  -- call createThreads with storable vector of function pointers, and number of threads - createThreads will spawn threads which will use  function pointers for callback
  SV.unsafeWith fv $ \x -> createThreads x (fromIntegral $ length threads)

请忽略代码中的不安全部分 - 我的目标是使用带有多线程C代码的Haskell FFI测试回调。当我编译它并运行它时，我得到以下错误：

$ ghc -O2 t.hs mt.c -lpthread
[1 of 1] Compiling Main             ( t.hs, t.o )
Linking t ...
$ ./t
main waiting for all threads to terminate...
t: schedule: re-entered unsafely.
   Perhaps a 'foreign import unsafe' should be 'safe'?
$ uname -a
Darwin desktop.local 11.2.0 Darwin Kernel Version 11.2.0: Tue Aug  9 20:54:00 PDT 2011; root:xnu-1699.24.8~1/RELEASE_X86_64 x86_64
$ ghc --version
The Glorious Glasgow Haskell Compilation System, version 7.0.3

只有在我有C线程回调haskell函数f时才会发生调度错误。我想我的代码中存在一个错误，而不是其中一个库或GHC中存在错误。所以，我想先在这里查看有关错误原因的指示。

Answer 1

在这种情况下，发生schedule错误是因为haskell代码是在没有-threaded选项的情况下编译的。

haskell代码调用C函数create_threads，它为threadFunc C函数生成多个线程。 threadFunc调用Haskell函数f。因此，即使编译Haskell代码时没有-threaded选项，它仍会导致多个C线程执行f。

GHC运行时调度程序很好地捕获了在没有线程运行时执行多个线程的监督，并将其标记为错误。这比一次神秘的运行时崩溃要好得多。当我在GHC代码库中检查rts/schedule.c代码时，我意识到了疏忽，并看到了下面的评论。它让我知道threaded运行时未启用：

// Check whether we have re-entered the RTS from Haskell without
 // going via suspendThread()/resumeThread (i.e. a 'safe' foreign
 // call).

使用Haskell回调函数调用多线程C FFI时计划错误

1 个答案: