Question

有没有办法可以用例如。

替换字符串中第一个字符实例

^1402 WSN NIAMLAB^teertS htimS 005

是

&1402 WSN NIAMLAB^teertS htimS 005

保持第二个^到位

Answer 1

要替换字符的第一个实例，我建议使用STUFF和CHARINDEX函数。 STUFF将字符串插入另一个字符串。它删除起始位置的第一个字符串中指定长度的字符，然后将第二个字符串插入起始位置的第一个字符串中。

DECLARE @str varchar(100) = '^1402 WSN NIAMLAB^teertS htimS 005'
SELECT STUFF(@str, CHARINDEX('^', @str), 1, '&')

请注意，您还可以在查询中使用STUFF，如下所示：

SELECT STUFF(<yourcolumn>, CHARINDEX('^', <yourcolumn>), 1, '&')
FROM <yourtable>

Answer 2

虽然您的问题中的示例是如何仅替换char的第一次出现，但是您的标题表示您要替换第n次出现，这有点棘手。

我写了一个函数，以找到字符串中第n个字符的出现。你可以使用比使用SUBSTRING构造一个字符串。

if exists (
    select 1
    from dbo.sysobjects 
    where id = object_id(N'[dbo].[CHARINDEX3]') 
        and xtype in (N'FN', N'IF', N'TF'))
begin
    drop function [dbo].[CHARINDEX3]
end

GO

/*
Example:
SELECT dbo.CHARINDEX3('a', 'abb abb a', 3)
SELECT dbo.CHARINDEX3('b', 'abb abb a', 5)
SELECT dbo.CHARINDEX3('a', 'abbabba', 3)
SELECT dbo.CHARINDEX3('b', 'abbabba', 5)
If @occurance > the max Occurrence, the function will return the max Occurrence
*/

CREATE FUNCTION dbo.CHARINDEX3
(
    @TargetStr char(1), 
    @SearchedStr varchar(max), 
    @Occurrence int
)
RETURNS INT
AS
BEGIN
    DECLARE @ret INT

    ; WITH
      -- Tally table Gen            Tally Rows:     X2                X3
      t1 AS (SELECT 1 N UNION ALL SELECT 1 N),    -- 4            ,    8
      t2 AS (SELECT 1 N FROM t1 x, t1 y),            -- 16            ,    64
      t3 AS (SELECT 1 N FROM t2 x, t2 y),            -- 256            ,    4096
      t4 AS (SELECT 1 N FROM t3 x, t3 y),            -- 65536        ,    16,777,216
      t5 AS (SELECT 1 N FROM t4 x, t4 y),            -- 4,294,967,296,    A lot
      Numbers AS (SELECT ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) Num
                  FROM t3 x, t3 y)
    SELECT TOP 1 @ret = Num 
    FROM
    (
        SELECT Ident = ROW_NUMBER() OVER (ORDER BY N.Num), N.Num 
        FROM Numbers N
        WHERE N.Num <= DATALENGTH(@SearchedStr)
            AND SUBSTRING(@SearchedStr, N.Num, DATALENGTH(@TargetStr)) = @TargetStr
    ) R 
    WHERE Ident <= @Occurrence
    ORDER BY Ident DESC

    RETURN @ret
END

GO

使用该函数，您可以获得第n次出现的位置，并简单地在出现之前和之后拉出所有字符，替换特定值。

--Actual Code
DECLARE @loc INT
DECLARE @MyStr VARCHAR(200)
DECLARE @replacement CHAR(1)

SET @MySTr = '^1402 WSN NIAMLAB^teertS htimS 005'
SET @replacement = '$'
SELECT @loc = dbo.CHARINDEX3('^',@MyStr, 2)

SELECT SUBSTRING(@myStr, 1, @loc-1) + @replacement + SUBSTRING(@MyStr, @loc + 1, LEN(@MyStr)-@loc)

此示例仅使用^

替换第二个$

Answer 3

未经测试的代码：

SELECT STUFF('^1402 WSN NIAMLAB^teertS htimS 005', charindex('^', '^1402 WSN NIAMLAB^teertS htimS 005'), 1, '&');
GO

但是，如果该角色不存在，您可能希望用{/ 1}}上的if / then包围该角色

仅替换第n个字符实例

3 个答案: