Question

假设我有这个：

-record(my_record, {foo, bar, baz}).

Keyvalpairs = [{foo, val1},
               {bar, val2},
               {baz, val3}].

Foorecord = #my_record{foo=val1, bar=val2, baz=val3}.

如何将Keyvalpairs转换为Foorecord？

Answer 1

最简单的事情是：

Foorecord = #my_record{foo=proplists:get_value(foo, Keyvalpairs), 
      bar=proplists:get_value(bar, Keyvalpairs),
      baz=proplists:get_value(baz, Keyvalpairs)}.

如果这种情况过于重复，您可以执行以下操作：

Foorecord = list_to_tuple([my_record|[proplists:get_value(X, Keyvalpairs)
      || X <- record_info(fields, my_record)]]).

Answer 2

与其他答案一样，您需要推出自己的解决方案来实现这一目标。然而，提出的解决方案是不完整例如，它不考虑记录条目的默认值。我使用以下代码片段来处理此转换：

%% @doc returns a "RECSPEC" that can be used by to_rec in order to 
%% perform conversions
-define(RECSPEC(R), {R, tuple_to_list(#R{}), record_info(fields, R)}).

%% @doc converts a property list into a record.
-spec to_rec(recspec(), proplist()) -> record().
to_rec({R, [_ | N], Spec}, P) when is_atom(R) and is_list(Spec) ->
    list_to_tuple(
      [R | lists:foldl(
         fun ({K,V}, A) ->
             case index_of(K, Spec) of
                 undefined -> 
                     A;
                 I -> 
                     {Head, Tail} = lists:split(I, A),
                      Rest = case Tail of
                                [_ | M] -> M;
                                []      -> []
                            end,
                     Head ++ [V | Rest]
             end
         end, N, P)]).

现在可以做到：

-record(frob, {foo, bar="bar", baz}).

to_rec(?RECSPEC(frob), [{baz, "baz"}, {foo, "foo"}])

产生

#frob{foo="foo", bar="bar", baz="baz"}

我把它放到我正在构建的一个小“工具箱”库中，以收集这些只是在开发Erlang应用程序时让生活更轻松的“片段”：ETBX

Answer 3

如果您的值与记录中的顺序相同，则可以直接转换为记录，您只需要在列表的第一个元素的记录名称前面，然后将列表转换为元组

Foorecord = list_to_tuple([my_record]++[Val || {_,Val} <- [{foo, val1},{bar, val2},{baz, val3}] ]).

如何将元组对列表转换为Erlang中的记录？

3 个答案: