Question

我正在使用递归模板来搜索某些特定元素：

<xsl:template name="GetProdDependency">
    <xsl:param name="TechProd"></xsl:param>
    <xsl:param name="BeatenPath"></xsl:param>
    <xsl:variable name="TechProdArch" select="$TechProd/pro:own_slot_value[pro:slot_reference='technology_product_architecture']/pro:value"></xsl:variable>
    <xsl:variable name="TechProdArchNode" select="/node()/pro:simple_instance[pro:name=$TechProdArch]"></xsl:variable>
    <xsl:variable name="TechProdCompList" select="$TechProdArchNode/pro:own_slot_value[pro:slot_reference='contained_techProd_components']/pro:value"/>
    <xsl:for-each select="$TechProdCompList">
        <xsl:variable name="TechProdAsRole" select="/node()/pro:simple_instance[pro:name=current()]/pro:own_slot_value[pro:slot_reference='technology_product_as_role']/pro:value"/>
        <xsl:variable name="TechProdRole" select="/node()/pro:simple_instance[pro:name=$TechProdAsRole]/pro:own_slot_value[pro:slot_reference='role_for_technology_provider']/pro:value"/>
        <xsl:variable name="DepTechProd" select="/node()/pro:simple_instance[pro:name=$TechProdRole]"/>
        <!-- Check for beaten Path -->
        <!-- if $DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value in BeatenPath -->
        <xsl:if test="not($BeatenPath[string(.)=string($DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value)])"> 
            <!-- Do the recursion here! -->
            <!--<xsl:value-of select="$DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"/> (type: <xsl:value-of select="$DepTechProd/pro:type"/> and Class: <xsl:value-of select="$DepTechProd/pro:name"/>)-->
            <!--<xsl:value-of select="$DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"/>-->
            <xsl:value-of select="$DepTechProd"/>
            <xsl:call-template name="GetProdDependency">
                <xsl:with-param name="TechProd" select="$DepTechProd"></xsl:with-param>
                <xsl:with-param name="BeatenPath" select="$TechProd|$DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"></xsl:with-param>
                <xsl:with-param name="Rev" select="$Rev + 1"></xsl:with-param>
            </xsl:call-template>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

这在搜索等方面运作良好。

但是当我在原始调用者中得到结果时，我希望从调用中获得一个节点列表。

我称之为：

<xsl:variable name="DelPlist">
<xsl:call-template name="GetProdDependency">
    <xsl:with-param name="TechProd" select="$TechProd"></xsl:with-param>
    <xsl:with-param name="BeatenPath" select="$TechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"></xsl:with-param>
    <xsl:with-param name="Rev" select="1"></xsl:with-param>
</xsl:call-template>
</xsl:variable>

我希望得到一个节点列表，我可以使用<xsl:for-each>进行迭代。但是，如果我检查count($DelPlist)，我得到1作为结果，我不能迭代。

有人可以帮忙吗？

Answer 1

你的问题的答案是：在XSLT 2.0中是的，在XSLT 1.0中没有。

在XSLT 2.0中，模板和函数都可以返回任何值。可以使用as属性指定结果的类型（例如as =“node（）*”），并且可以使用xsl：sequence指令将结果设置为任何XPath表达式的结果。

在XSLT 1.0中，如果在变量中捕获xsl：call-template的结果，则变量的值将始终为结果树片段。

Answer 2

您必须在as属性中指定模板结果的类型。

如果未指定，则类型为document-node()，然后为了遍历结果，您需要获取结果的子项。

解决方案：指定具有as属性的模板的返回类型。

以下是完整示例：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:variable name="vNodes" as="element()*">
      <xsl:call-template name="genNodes"/>
     </xsl:variable>

     <xsl:for-each select="$vNodes">
      <xsl:value-of select="concat('&#xA;', position(), ': ')"/>
      <xsl:copy-of select="."/>
     </xsl:for-each>
 </xsl:template>

 <xsl:template name="genNodes" as="element()*">
  <a/>
  <b/>
  <c/>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于任何XML文档（未使用）时，会生成所需的正确结果：

1: <a/>
2: <b/>
3: <c/>

Answer 3

很抱歉打扰。

我可以通过以下内容达到我的要求：

<xsl:template name="GetProdDependency">
    <xsl:param name="TechProd"></xsl:param>
    <xsl:param name="BeatenPath"></xsl:param>
    <xsl:variable name="TechProdArch" select="$TechProd/pro:own_slot_value[pro:slot_reference='technology_product_architecture']/pro:value"></xsl:variable>
    <xsl:variable name="TechProdArchNode" select="/node()/pro:simple_instance[pro:name=$TechProdArch]"></xsl:variable>
    <xsl:variable name="TechProdCompList" select="$TechProdArchNode/pro:own_slot_value[pro:slot_reference='contained_techProd_components']/pro:value"/>
    <xsl:for-each select="$TechProdCompList">
        <xsl:variable name="TechProdAsRole" select="/node()/pro:simple_instance[pro:name=current()]/pro:own_slot_value[pro:slot_reference='technology_product_as_role']/pro:value"/>
        <xsl:variable name="TechProdRole" select="/node()/pro:simple_instance[pro:name=$TechProdAsRole]/pro:own_slot_value[pro:slot_reference='role_for_technology_provider']/pro:value"/>
        <xsl:variable name="DepTechProd" select="/node()/pro:simple_instance[pro:name=$TechProdRole]"/>
        <!-- Check for beaten Path -->
        <!-- if $DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value in BeatenPath -->
        <xsl:if test="not($BeatenPath[string(.)=string($DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value)])"> 
            <!-- Do the recursion here! -->
            <!--<xsl:value-of select="$DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"/> (type: <xsl:value-of select="$DepTechProd/pro:type"/> and Class: <xsl:value-of select="$DepTechProd/pro:name"/>)-->
            <!--<xsl:value-of select="$DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"/>-->
            <!--<xsl:value-of select="$DepTechProd"/>-->
            <xsl:element name="TProd">
                <xsl:value-of select="$DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value" />
            </xsl:element>
            <xsl:call-template name="GetProdDependency">
                <xsl:with-param name="TechProd" select="$DepTechProd"></xsl:with-param>
                <xsl:with-param name="BeatenPath" select="$TechProd|$DepTechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"></xsl:with-param>
                <xsl:with-param name="Rev" select="$Rev + 1"></xsl:with-param>
            </xsl:call-template>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

并且可以遍历节点列表：

<xsl:variable name="DelPlist">
<xsl:call-template name="GetProdDependency">
    <xsl:with-param name="TechProd" select="$TechProd"></xsl:with-param>
    <xsl:with-param name="BeatenPath" select="$TechProd/pro:own_slot_value[pro:slot_reference='name']/pro:value"></xsl:with-param>
    <xsl:with-param name="Rev" select="1"></xsl:with-param>
</xsl:call-template>
</xsl:variable>

<xsl:for-each select="$DelPlist/node()">
    <xsl:value-of select="current()" />
</xsl:for-each>

符合我目前的要求。

Answer 4

可能在xsl 1.0中使用exslt：node-set（大多数xslt处理器支持）：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exslt="http://exslt.org/common"
    xmlns:msxml="urn:schemas-microsoft-com:xslt"
    exclude-result-prefixes="exslt msxml"
    extension-element-prefixes="exslt msxml"
    version="1.0">
    <!-- support for exslt prefix for msxml, ignored by other processors which however support exsl natively anyway -->
    <msxml:script language="JScript" implements-prefix="exslt">this['node-set']=function(x){return x}</msxml:script>
    <xsl:template match="/">
        <xsl:variable name="elementsReturnedFromCallTemplate">
            <xsl:call-template name="getElements"/>
        </xsl:variable>
        <xsl:for-each select="exslt:node-set($elementsReturnedFromCallTemplate)/*">
            <xsl:copy/>
        </xsl:for-each>
    </xsl:template>
    <xsl:template name="getElements">
        <a/>
        <b/>
    </xsl:template>
</xsl:stylesheet>

输出（在libxslt，xalan，saxon，msxml中测试）：

<a/>
<b/>

xsl：命名模板可以返回节点列表吗？

4 个答案: