Question

Common Lisp中“set”，“setq”和“setf”有什么区别？

Answer 1

最初，在Lisp中，没有词汇变量 - 只有动态变量。和没有SETQ或SETF，只有SET功能。

现在写成：

(setf (symbol-value '*foo*) 42)

写成：

(set (quote *foo*) 42)

最终缩写为SETQ（SET Quoted）：

(setq *foo* 42)

然后发生了词汇变量，并且SETQ也被用于赋值给它们 - 所以它不再是SET的简单包装。

后来，有人发明了SETF（SET Field）作为向数据结构赋值的通用方法，以反映其他语言的l值：

x.car := 42;

将写为

(setf (car x) 42)

为了对称性和通用性，SETF还提供了SETQ的功能。在这一点上，说SETQ是低级原语，SETF是高级操作是正确的。

然后发生了符号宏。因此，符号宏可以透明地工作，如果被赋予的“变量”实际上是一个符号宏，则认识到SETQ必须像SETF一样：

(defvar *hidden* (cons 42 42))
(define-symbol-macro foo (car *hidden*))

foo => 42

(setq foo 13)

foo => 13

*hidden* => (13 . 42)

所以我们到了今天：SET和SETQ是老式方言的萎缩遗骸，可能会从Common Lisp的最终继承者中启动。

Answer 2

(set ls '(1 2 3 4)) => Error - ls has no value

(set 'ls '(1 2 3 4)) => OK

(setq ls '(1 2 3 4)) => OK - make ls to (quote ls) and then have the usual set

(setf ls '(1 2 3 4)) => OK - same as setq so far BUT

(setf (car ls) 10) => Makes ls '(10 2 3 4) - not duplicated by setq/set

Answer 3

setq就像set一样引用第一个arg - (set 'foo '(bar baz))就像(setq foo '(bar baz))一样。另一方面，setf确实很微妙 - 它就像一个“间接”。我建议http://www.n-a-n-o.com/lisp/cmucl-tutorials/LISP-tutorial-16.html作为开始理解它的更好方式，而不是这里的任何答案都可以给出......但是，setf将第一个参数作为“参考”，例如(aref myarray 3)将在数组中设置一个项目（作为setf的第一个参数）。

Answer 4

您可以使用setf代替set或setq，但不能反之亦然，因为setf还可以设置变量的各个元素的值个别元素。见下面的exaples：

所有四个示例都会将列表（1,2,3）分配给名为foo的变量。

(set (quote foo) (list 1 2 3))    ;foo => (1 2 3)
(1 2 3)

(set 'foo '(1 2 3))   ;foo => (1 2 3) same function, simpler expression
(1 2 3)

(setq foo '(1 2 3))   ;foo => (1 2 3) similar function, different syntax
(1 2 3)

(setf foo '(1 2 3))   ;foo => (1 2 3) more capable function
(1 2 3)

setf具有将foo中的列表成员设置为新值的附加功能。

foo                   ;foo => (1 2 3) as defined above
(1 2 3)

(car foo)             ;the first item in foo is 1
1

(setf (car foo) 4)    ;set or setq will fail since (car foo) is not a symbol
4

foo                   ;the fist item in foo was set to 4 by setf
(4 2 3)

但是，您可以定义代表foo

中单个项目的符号宏

(define-symbol-macro foo-car (car foo))    ; assumes FOO => (1 2 3)
FOO-CAR

foo-car               ;foo-car is now a symbol for the 1st item in foo
1

(setq foo-car 4)      ;set or setq can set the symbol foo-car 
4

foo                   ;Lisp macros are so cool
(4 2 3)

如果您尚未定义变量并且不希望在代码中稍后为其提供值，则可以使用defvar。

(defvar foo2)
(define-symbol-macro foo-car (car foo2))

Answer 5

可以认为SET和SETQ是低级构造。

SET可以设置符号的值。
SETQ可以设置变量的值。

然后SETF是一个宏，它提供了多种设置：符号，变量，数组元素，实例槽，......

对于符号和变量，可以认为SETF扩展为SET和SETQ。

* (macroexpand '(setf (symbol-value 'a) 10))

(SET 'A 10)


* (macroexpand '(setf a 10))         

(SETQ A 10)

因此SET和SETQ用于实现SETF的一些功能，这是更通用的构造。当我们考虑符号宏时，其他一些答案会告诉你稍微复杂的故事。

Answer 6

我想在之前的答案中添加setf是宏，它根据作为第一个参数传递的内容调用特定函数。将setf的宏扩展结果与不同类型的参数进行比较：

(macroexpand '(setf a 1))

(macroexpand '(setf (car (list 3 2 1)) 1))

(macroexpand '(setf (aref #(3 2 1) 0) 1))

对于某些类型的参数，将调用“setf function”：

(defstruct strct field)
(macroexpand '(setf (strct-field (make-strct)) 1))

Common Lisp中`set`，`setq`和`setf`之间的区别？

6 个答案: