Question

我在这里搜索，发现有人使用这个

set is_dir=0
for %%i in ("%~1") do if exist "%%~si"\nul set is_dir=1

但是没有用，当%1==c:\this is a file with spaces.csproj时，测试仍然成功，这意味着它仍将被视为文件夹!!!

任何人都知道答案，我想这是一个非常普遍的问题，Windows已经存在很多年了，应该有一个非常简单的解决方案....

Answer 1

我知道用于在MS-DOS上工作的文件夹的if exist path\nul测试。我不知道它是否因引入长文件名而被打破。

我知道if exist "long path\nul"在Windows批处理中不起作用。我直到今天才意识到if exist path\nul只要路径是短的8.3形式，就可以在Vista上工作。

原始代码似乎适用于Vista。它似乎也适用于XP，但我相信以下XP错误会妨碍：Batch parameter %~s1 gives incorrect 8.3 short name。

原始代码不需要FOR循环，只需使用%~s1

即可

以下是将路径完全分类为INVALID，FILE或FOLDER的变体。它适用于Vista，但由于%~s1错误而无法在XP上运行。我不确定它在MS-DOS上的表现如何 编辑2015-12-08：有许多Windows失败的情况

@echo off
if not exist "%~1" ( set "type=INVALID" ) else if exist %~s1\nul ( set "type=FOLDER" ) else ( set "type=FILE" )
@echo "%~1" = %type%

我相信这种变体适用于几乎所有版本的Microsoft批处理，包括MS-DOS和XP。（它显然不适用于不支持PUSHD的DOS早期版本）

@echo off
if exist "%~1" (2>nul pushd "%~1" && (popd&set "type=FOLDER") || set "type=FILE" ) else set "type=INVALID"
echo "%~1" = %type%

更新2014-12-26

我很确定以下内容适用于从XP开始的所有Windows版本，但我只在Win 7上测试过。
编辑2015-12-08：这可能会在网络驱动器上失败，因为文件夹测试可能会错误地将文件报告为文件夹

@echo off
if exist %1\ (
  echo %1 is a folder
) else if exist %1 (
  echo %1 is a file
) else (
  echo %1 does not exist
)

更新2015-12-08

最后 - 一个真正应该适用于XP以后的任何Windows版本的测试，包括网络驱动器和UNC路径

for /f "tokens=1,2 delims=d" %%A in ("-%~a1") do if "%%B" neq "" (
  echo %1 is a folder
) else if "%%A" neq "-" (
  echo %1 is a file
) else (
  echo %1 does not exist
)

Answer 2

我只是这样试过。希望这会有所帮助。

@ECHO OFF
SET CURR_DIR=%CD%
SET IS_DIR=0
CD %1% 
IF "%ERRORLEVEL%"=="0" SET IS_DIR=1
CD %CURR_DIR%
ECHO IS DIRECTORY %IS_DIR%

输出：

D:\Work\Stand alone Java classes>test.bat D:\Work\Training
IS DIRECTORY 1

D:\Work\Stand alone Java classes>test.bat D:\Work\Training\SRT.txt
The directory name is invalid.
IS DIRECTORY 0

Answer 3

“dir”命令的/ ad选项列出文件夹，/ b选项为裸。假设您已检查文件是否存在，请使用：

dir /ad /b ChangeThisToYourFilename 1> NUL 2> NUL
if %ERRORLEVEL% EQU 0 (
    echo is a file
) else (
    echo is NOT a file
)

Answer 4

对于1班轮：

dir /a:d /b C:\Windows 2>&1 | findstr /i /n /c:"File Not Found">nul && (@echo. Im a file) || (@echo. Im a folder)

e.g。将C:\Windows更改为C:\Windows\Notepad.exe

-Sorry Arun，dbenham，没读过你的！与......相同。

Answer 5

This solution组合了文件属性parameter extension（%~a1）和variable substring extraction（%variable:~0,1%）：

@ECHO OFF

CALL :is_directory C:\Windows
CALL :is_directory C:\MinGW\share\doc\mingw-get\README
CALL :is_directory C:\$Recycle.Bin
CALL :is_directory "C:\Documents and Settings"
CALL :is_directory "%LOGONSERVER%\C$\Users\All Users"

GOTO :EOF

:is_directory
    SETLOCAL
    SET file_attribute=%~a1
    IF "%file_attribute:~0,1%"=="d" (
        ECHO %file_attribute% %1 is a directory
    ) ELSE (
        ECHO %file_attribute% %1 is NOT a directory
    )
    ENDLOCAL
    GOTO :EOF

输出：

d-------- C:\Windows is a directory
--a------ C:\MinGW\share\doc\mingw-get\README is NOT a directory
d--hs---- C:\$Recycle.Bin is a directory
d--hs---l "C:\Documents and Settings" is a directory
d--hs---l "\\MYCOMPUTER\C$\Users\All Users" is a directory

Answer 6

以前，我使用"\nul"方法，但很长一段时间以来，我使用"\*"来测试现有的filespec是文件夹还是文件。据我所知，它适用于Windows的所有版本，从Windows 95（可能还有早期版本）到所有当前的Windows版本。

因此，与其他方法一样，首先测试文件是否存在。然后，要查看它是否为＆＃34;文件夹＆＃34;，请使用以下内容对其进行测试：if exist "%fspec%\*"：

if not exist "%fspec%"   goto :NotExistOrInvalid

rem "%fspec%" is "Valid" and is either a "Folder", or a "File".
if     exist "%fspec%\*" goto :IsValidAndIsAFolder

rem "%fspec%" is a "File" (a "Regular File" or a Shortcut/Link).
goto :IsValidAndIsAFile

例如：

set "fspec=XYZ:%perlpath%"
if not exist "%fspec%" echo "%fspec%": Invalid or not found && rem Invalid, goto :NotExistOrInvalid

set "fspec=%perlpath%"
if not exist "%fspec%" echo "%fspec%": Invalid or not found && rem goto :NotExistOrInvalid

rem "%fspec%" Is a "Valid" filespec and is either a "Folder", or a "File".
if exist "%fspec%\*" (echo "%fspec%" is a "Folder".) else echo "%fspec%" is a "File".

set "fspec=%perlpath%\perl.exe"
if not exist "%fspec%" echo "%fspec%": Invalid or not found && rem Invalid, goto :NotExistOrInvalid

rem "%fspec%" Is a "Valid" filespec and is either a "Folder", or a "File".
if exist "%fspec%\*" (echo "%fspec%" is a "Folder".) else echo "%fspec%" is a "File".

这个输出是：

"XYZ:F:\usr\perl\bin": Invalid or not found
"F:\usr\perl\bin" is a "Folder".
"F:\usr\perl\bin\perl.exe" is a "File".

如何测试路径是Windows批处理文件中的文件或目录？

6 个答案: